topic Re: Quickest way to get a single observation from a dataset in SAS Programming

Quickest way to get a single observation from a dataset

user24feb — Fri, 24 Oct 2014 06:56:34 GMT

Hello!

I need to create a dataset containing a single observation from a large dataset and create a macro-variable. Is the point option the quickest way to do this?

Options Fullstimer;
%Let Pos=1000;

Data A (Drop=i);
Do i=1 To 1000000;
X=Ranuni(1); Output;
End;
Run;

Data B;
Obs=&Pos.;
Set A Point=Obs;
Call SymputX('MVB',X);
Output;
Stop;
Run;
%Put **&MVB.**;

Data D;
Set A (FirstObs=&Pos. Obs=&Pos.);
Call SymputX('MVD',X);
Run;
%Put **&MVD.**;

Thanks&kind regards

Re: Quickest way to get a single observation from a dataset

Ksharp — Fri, 24 Oct 2014 15:54:33 GMT

Yeah. Maybe, it is random access method. And you can also try this way, compare them who is faster .

%let dsid=%sysfunc(open(sashelp.class,i));
%global name;
%syscall set(dsid);
%let rc=%sysfunc(fetchobs(&dsid,10));
%let rc=%sysfunc(close(&dsid));

%put &name;

Xia Keshan

Re: Quickest way to get a single observation from a dataset

data_null__ — Fri, 24 Oct 2014 16:00:36 GMT

Looks like you've answered your own question. What did the FULLSTIMER stats show in your log.