topic Re: Question about assigning labels in SAS Programming

Question about assigning labels

spirto — Mon, 13 Jan 2014 17:08:59 GMT

Hi all,

I am converting a character variable to numeric and want the numeric variable to have the same label as the character variable but am not sure how to do this. See example code below:

data blah(drop=var1_c); set blahblah(rename=(var1=var1_c));

var1=input(var1_c,1.);

label var1=*same label as var1_c*;

run;

Re: Question about assigning labels

art297 — Mon, 13 Jan 2014 17:29:33 GMT

Use the call label routine. It is documented at: SAS(R) 9.2 Language Reference: Dictionary, Fourth Edition

The syntax is simply:

CALL LABEL(variable1,variable2);

which assigns the label from variable1 to the character variable variable2

Re: Question about assigning labels

data_null__ — Mon, 13 Jan 2014 17:38:10 GMT

I don't think that will do what wants.

Re: Question about assigning labels

data_null__ — Mon, 13 Jan 2014 17:41:00 GMT

You seek the "holly grail" of type conversion. :smileymischief:

Re: Question about assigning labels

spirto — Mon, 13 Jan 2014 17:46:27 GMT

Correct. I tried Art's suggestion and it did not work. @data_null_: im assuming that this conversion is something that everyone wants but there is no easy solution?

Re: Question about assigning labels

Reeza — Mon, 13 Jan 2014 18:07:21 GMT

You can use vlabel to get the label in one step and then a proc datasets to assign the label but still not really nice in many ways.

data blah(drop=var1_c); set blahblah(rename=(var1=var1_c));

var1=input(var1_c,1.);

call symput (var1_label, vlabel(var1_c));

run;

proc datasets lib =work nolist nodetails;

modify blah;

label var1="&var1_label";

run; quit;

Re: Question about assigning labels

data_null__ — Mon, 13 Jan 2014 18:08:59 GMT

I'ts not difficult but there is no function to assign a label in a data step. How many variables are you converting? How many different informats?

Re: Question about assigning labels

spirto — Mon, 13 Jan 2014 18:21:12 GMT

Usually converting 5-6 variables per dataset. Not using any informats since the variables are already coming from a SAS dataset. So really I am not converting too many variables but its five too many to label manually :smileysilly:.

Re: Question about assigning labels

Fugue — Mon, 13 Jan 2014 18:40:18 GMT

Would something like this work for you?

http://support.sas.com/resources/papers/proceedings10/047-2010.pdf

Re: Question about assigning labels

art297 — Mon, 13 Jan 2014 18:54:52 GMT

Sorry for not having first tested my suggestion. You and DN are definitely correct, it won't work as I suggested.

However John's paper, as referenced by , should work.

If you only have one variable that you want to reassign a label to, the following will also work (yes, I did test it this time):

data blahblah;

label var1='first variable';

input var1 $;

cards;

;

filename relabel temp;

data _null_;

set blahblah;

file relabel;

length label $32;

call label(var1,label);

put "data blah (drop=var1_c);";

put "set blahblah (rename=var1=var1_c);";

put "label var1=:"@;

put label @;

put ";";

put "var1=input(var1_c,1.);";

put "run;";

run;

%include relabel;

Re: Question about assigning labels

spirto — Mon, 13 Jan 2014 19:44:35 GMT

Thank you all for your suggestions. I was hoping there was a function to the likes of label var1=getlabel(var1_c); but wouldn't we all

Re: Question about assigning labels

data_null__ — Tue, 14 Jan 2014 11:57:46 GMT

I thing this technique is interesting and demonstrates interesting features, and default behavior, of PROC TRANSPOSE.

proc datasets kill noprint nolist; 
   run; 
   quit; 
data class;
   infile cards dsd; 
   input (Name Sex Age Height Weight) (:$8.);
   attrib age     label='Age (years)'; 
   attrib height  label='Height (inches)'; 
   attrib weight  label='Weight (lbs.)'; 
   attrib sex     label='Gender'; 
   cards; 
"Alfred","M","14","69","112.5"
"Alice","F","13","56.5","84"
"Barbara","F","13","65.3","98"
"Carol","F","14","62.8","102.5"
"Henry","M","14","63.5","102.5"
"James","M","12","57.3","83"
"Jane","F","12","59.8","84.5"
"Janet","F","15","62.5","112.5"
"Jeffrey","M","13","62.5","84"
"John","M","12","59","99.5"
"Joyce","F","11","51.3","50.5"
"Judy","F","14","64.3","90"
"Louise","F","12","56.3","77"
"Mary","F","15","66.5","112"
"Philip","M","16","72","150"
"Robert","M","12","64.8","128"
"Ronald","M","15","67","133"
"Thomas","M","11","57.5","85"
"William","M","15","66.5","112"
;;;;
   run; 
proc transpose data=class out=tall;
   by Name;
   copy Sex;
   var Age Height Weight;
   run; 
proc print; 
   run; 
data convert / view=convert;
   set tall;
   num1 = input(col1,comma16.);
   run; 
proc transpose data=convert out=class2(drop=_name_);
   by Name;
   copy Sex;
   var num1;
   run; 
proc print; 
   run;

Re: Question about assigning labels

Tom — Tue, 14 Jan 2014 14:27:06 GMT

Personally I have a utility macro function I have been using for 15 years that will return information about a particular variable from an existing dataset which makes this problem easy.

data blah(drop=var1_c);

set blahblah(rename=(var1=var1_c));

var1=input(var1_c,1.);

label var1="%varexist(blahblah,var1,label)";

run;

Re: Question about assigning labels

spirto — Tue, 14 Jan 2014 15:43:34 GMT

Tom, is your macro publicly available?

Re: Question about assigning labels

kuridisanjeev — Thu, 16 Jan 2014 05:25:54 GMT

Hi,

Interesting Question...initially i thought it was very easy to assign labels from one variable to another,but when i put my fingers on the key board,my brain stopped working.:smileysilly:

any how I tried bellow code.i know this was lengthy and not so effective method also,but the good thing is it is working well.But I am getting

"Variable is uninitialized" note in the log.

Is there any way avoid this note,i mean could any one make some amendments to bellow code to prevent the Log note(Variable is uninitialized) ?

Data t;

input A A1 b c ;

label A ="Test";

label C ="Test1";

A_char=put(A,1.);

C_char=put(C,1.);

cards;

2 5 5 9

4 8 8 8

;

run;

Proc contents data=t out=lab(keep=name label where=(not missing(label)));

run;

Proc Sql;

Select compress(Name||"_char"||"="||' " '||label||' " ') into : labs separated by ' ' from lab;

quit;

Data new;

set T;

label &labs;

run;

Thanks for your time..

Reagrds,

Sanjeev.K

Message was edited by: Sanjeev Kuridi Code working perfect now. I have updated the code as Art suggested.

Re: Question about assigning labels

dishant — Thu, 16 Jan 2014 06:10:11 GMT

Hi,

You can use vlabel to get the label in one step and then a proc datasets to assign the label.The Following Is My code.

data chk;

input var_C $;

label var_c="First Variable";

datalines;

;

Run;

data chk1(drop=var1_cC);

set chk (rename=(var_c=var1_CC));

var_N=input(var1_CC,6.);

call symput ("var1_label",vlabel(var1_cC));

Run;

%put &var1_label;

proc datasets lib =work nolist nodetails;

modify chk1;

label var_N="&var1_label";

run; quit;

If Any concern Pls Let Me know.

Regards,

Dishant Parikh

Re: Question about assigning labels

art297 — Thu, 16 Jan 2014 06:12:20 GMT

: limit what is output from proc compare. e.g.:

Proc contents data=t

out=lab(keep=name label where=(not missing(label)));;

run;

Re: Question about assigning labels

kuridisanjeev — Thu, 16 Jan 2014 06:23:50 GMT

Thanks a lot !!!!...Sounds pretty Simple....

Not Sure how i missed this...

Sanjeev.k

Re: Question about assigning labels

Tom — Sun, 19 Jan 2014 03:36:38 GMT

%macro varexist(ds,var,info);

%local dsid rc varnum;

%*----------------------------------------------------------------------

Use the SYSFUNC macro to execute the SCL OPEN, VARNUM,

other variable information and CLOSE functions.

-----------------------------------------------------------------------;

%let dsid = %sysfunc(open(&ds));

%if (&dsid) %then %do;

%let varnum = %sysfunc(varnum(&dsid,&var));

%if (&varnum) & %length(&info) %then

%sysfunc(var&info(&dsid,&varnum))

;

%else

&varnum

;

%let rc = %sysfunc(close(&dsid));

%end;

%else 0;

%mend varexist;