topic Re: Datalines in macro in SAS Programming

Datalines in macro

Aman4SAS — Tue, 11 Mar 2014 13:23:01 GMT

I have a macro varible i.e

%let x =a|b|c|d|e|f ;

I want to creat a dataset

I tried by using datalines, but getting error,

can u please help me on this.

Thanks

Re: Datalines in macro

Haikuo — Tue, 11 Mar 2014 13:40:23 GMT

I don't think macro variables work below cards/datalines. Try this:

%let x =a|b|c|d|e|f ;

data want;

_temp=symget('x');

do _i=1 to countw(_temp,'|');

x=scan(_temp,_i,'|');

output;

end;

drop _:;

run;

Re: Datalines in macro

Astounding — Tue, 11 Mar 2014 13:50:58 GMT

A good approach, but consider a few items.

The number of values will be 1 + countw(...)

You don't really need SYMGET. You could just refer to "&x" instead of _temp.

The length of the variable X will be longer than you might expect ... perhaps better to set that length with a LENGTH statement early in the DATA step.

Re: Datalines in macro

data_null__ — Tue, 11 Mar 2014 14:04:27 GMT

The advantage of SYMGET is you don't have to worry about what quote characters might exist in the value of the macro variable or the setting of QUOTELENMAX.

Re: Datalines in macro

Aman4SAS — Tue, 11 Mar 2014 14:05:01 GMT

Yes agree with you that i need to +1 , But using macro variable directly is not working,[may be i m missing something]

I have mentioned below both example:

%let dt= 1|2|3|4|5;

data test2;

temp=symget('dt');

do i = 1 to count(temp,'|')+1;

x= scan(temp,i,"|");

output;

end;

run;

proc print; run;

data test2;

do i = 1 to count(&dt,'|')+1;

x= scan(&dt,i,"|");

output;

end;

run;

proc print; run;

Re: Datalines in macro

Astounding — Tue, 11 Mar 2014 14:14:02 GMT

In the final DATA step, you have to add the double quotes in two places: "&dt" not &dt

Also recommend adding a PROC CONTENTS so you can see the length assigned to X.

Re: Datalines in macro

data_null__ — Tue, 11 Mar 2014 14:53:45 GMT

There is really no need to count anything but you may want to account for delimiters contained in the words. And make sure to properly define the variables in the data step.

%let dt= 1|2|'3|4'|4|5;
data test2;
   length temp $256 x $8; 
   temp=symget('dt');
   do i = 1 by 1; 
      x=scan(temp,i,"|",'Q');
      if missing(x) then leave;
      output; 
      end; 
   stop; 
   drop temp;
   run;

Re: Datalines in macro

Reeza — Tue, 11 Mar 2014 14:58:17 GMT

Here's how I like to scan through a variable list and create my new macro variables.

%macro loop(varlist);

%let i=1;

%do %while (%scan(&varlist, &i, "|") ^=%str());

%let var=%scan(&varlist, &i, "|");

%put &var;

*rest of SAS code goes here;

*Increment counter;

%let i=%eval(&i+1);

%end;

%mend;

%let temp=a|b|c|d|e;

%loop(&temp);

Re: Datalines in macro

data_null__ — Tue, 11 Mar 2014 15:35:48 GMT

You are scanning twice and your delimiter list includes the double quote. I think you may need some macro quoting to protect your program from the words.

Re: Datalines in macro

Reeza — Tue, 11 Mar 2014 15:44:38 GMT

Thanks for the double quote correction.

I'm not too concerned about the scanning twice.

I usually use it to scan variable lists, so no issue with extra quotation marks, punctuation in the list.

Any other places that may need macro quoting?

Re: Datalines in macro

data_null__ — Tue, 11 Mar 2014 15:59:11 GMT

Variable list processing is best done with PROC TRANSPOSE. With transpose you can also process "SAS Variable Lists" like name range, prefix, and enumerated lists.

Re: Datalines in macro

slchen — Tue, 11 Mar 2014 16:42:43 GMT

%let x =a|b|c|d|e|f ;
data _null_;
file "c:\temp\temp.csv";
_file_="&x";
put;
run;

data want;
infile "c:\temp\temp.csv" dlm='|';
input x $ @@;
run;

Re: Datalines in macro

data_null__ — Tue, 11 Mar 2014 16:59:49 GMT

Do a search for "infile magic" to see how that and MORE are done in one data step.