topic Re: How to add the sum of a variable into the data set for every record in SAS Programming

How to add the sum of a variable into the data set for every record

Sunny4 — Mon, 15 Jan 2018 16:46:26 GMT

I have data

Required output is

id id_1

1 6

2 6

3 6

where 6= sum of id's

Re: How to get?

BrunoMueller — Mon, 15 Jan 2018 16:47:18 GMT

Interesting idea to sum up ID's.

If you know about SQL, you can use Proc SQL to solve this.

There are for sure other ways using DATA Step programming or using a Proc such as MEANS.

SQL sample:

data have;
  infile cards;
  input id;
cards;
1
2
3
;

proc sql;
  select
    id
    , (select sum(id) from have) as id_1
  from
    have
  ;
quit;

For next time: please provide a better subject line for the post, so that we have more information already in the title.

Find More information here

https://communities.sas.com/t5/Getting-Started/How-to-get-fast-helpful-answers/ta-p/226133/jump-to/first-unread-message

Re: How to add the sum of a variable into the data set for every record

Reeza — Mon, 15 Jan 2018 16:46:56 GMT

@Sunny4 note that I've modified your subject line to be more descriptive of your question.

Re: How to add the sum of a variable into the data set for every record

art297 — Mon, 15 Jan 2018 17:02:23 GMT

Here is one proc+datastep method:

data have;
  input id;
  datalines;
1
2
3
;

proc summary data=have;
  var id;
  output out=sum (drop=_:) sum=id_1;
run;

data want;
  set have;
  if _n_ eq 1 then set sum;
run;

Art, CEO, AnalystFinder.com

Re: How to add the sum of a variable into the data set for every record

mkeintz — Mon, 15 Jan 2018 23:48:26 GMT

And here's a single data step solution. It's still two passes through the data, but it's a single step.

data want;
  set have (in=firstpass)
      have (in=secondpass);
  if firstpass then sumid+id;
  if secondpass;
run;