topic Re: Conflicting Ages Generated using INTCK in SAS Programming

Conflicting Ages Generated using INTCK

LAsasuser79 — Tue, 09 Jan 2018 20:48:41 GMT

Hi All, I'm attempting to calculate age at Event (1st vaccination) for a data set I'm using. I've used this forum to find several different ways to calculate age at event, however, they all result in different values. I'm hoping to find out which of these calculations represents the true age at vaccination for this population.

A few details- I calculated participants age at the start of the study ( 12-1-2016), which gave me an age range of 7-21 yrs ( Agetest). I'm using version 9.4.

I want to exclude anyone who received a vaccination before age 9. Now, when I attempt to calculate participants' age at first vaccination ( Event), I get different values for how many are actually <9 at the event. With the coding below I get participants age at event as between 0-21. I'm assuming that some clinics erroneously listed the participant's dob and vaccination date as the same. What am I missing about this code that would explain these differences and which code reflects an accurate count at each age?

Here's the code I've used thus far;

data want; set have; today=MDY(12,01,2016);

days=today-BIRTH_DATE;

AGEtest= floor ((intck('month',BIRTH_DATE,today) - (day(today) < day(BIRTH_DATE))) / 12);*age at study start;

AgeatVacc=INTCK ('YEAR', BIRTH_DATE, CHVaccDate_1);run;

AgeVtest=floor ((intck('month',BIRTH_DATE,CHVaccDate_1) - (day(CHVaccDate_1) < day(BIRTH_DATE))) / 12); *age at first vacc date;

AgeVtest2=floor ((intck('month',BIRTH_DATE,CHVaccDate_1)) / 12);*looking at diff btw birth date and 1st vacc date- gives different answers;

AgeVTest5=floor ((intck('YEAR',BIRTH_DATE, CHVaccDate_1))); RUN;

Re: Conflicting Ages Generated using INTCK

Reeza — Tue, 09 Jan 2018 20:57:50 GMT

What about INTCK with the AGE option?

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Tue, 09 Jan 2018 21:06:53 GMT

Hi Reeza,

Do you mean something like AgeatEvent = INTCK('year',dob,eventdate,"Age") ? This generates missing values for the data.

Re: Conflicting Ages Generated using INTCK

PGStats — Tue, 09 Jan 2018 21:22:27 GMT

How about going back to basics, i.e. The Manual

The continuous method is useful for calculating anniversaries. For example, you can calculate the number of years a couple is married by executing the following program: 

data b;
   WeddingDay='14feb2000'd;
   Today=today();
   YearsMarried=intck('YEAR', WeddingDay, today(), 'C');
   format WeddingDay Today date9.;
run;

proc print data=b;
run;

The results are WeddingDay=14FEB2000, Today=01OCT2012, and YearsMarried=12.

Re: Conflicting Ages Generated using INTCK

Astounding — Tue, 09 Jan 2018 21:30:37 GMT

INTCK is tricky, and not a good idea for calculating AGE. It counts the number of boundaries crossed, not the number of intervals. For example:

age = intck('year', '28dec2016'd, '02jan2017'd); ==> 1, because 1 instance of January 1st is encountered

age = intck('year', '02jan2017'd, '31dec2017'd); ==> 0, because 0 instances of January 1st are encountered

You might find it easier to just count days. For example, an approximate formula would be:

if (CHVaccDate_1 - BIRTH_DATE) < (365 * 7) + (366 * 2) then delete;

Or you can experiment with a different function:

if CHVaccDate_1 < intnx('year', BIRTH_DATE, 9, 'same') then delete;

If haven't really tested that last one sufficiently, but there is definitely a combination that would work using INTNX.

Re: Conflicting Ages Generated using INTCK

PGStats — Tue, 09 Jan 2018 21:34:51 GMT

INTCK("YEAR", d1, d2, "CONTINUOUS") uses d1 as the year boundary, so it does calculate age (in years) appropriately.

Re: Conflicting Ages Generated using INTCK

Astounding — Tue, 09 Jan 2018 21:56:35 GMT

Excellent! Time for me to play with my new toy.

@PGStats solution works like a charm. One sample test program:

data test;

do d='14feb2016'd to '01mar2016'd;

age = intck('year', '20feb2015'd, d, 'continuous');

output;

end;

run;

proc print data=test;

title 'Start = February 20, 2015';

format d date9.;

run;

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Wed, 10 Jan 2018 01:52:26 GMT

This solution doesn't work because each event "wedding" date is different for each participant. This method works for calculating age of participant at study start, which I have used successfully.

Re: Conflicting Ages Generated using INTCK

Reeza — Wed, 10 Jan 2018 02:40:32 GMT

@LAsasuser79 wrote:
This solution doesn't work because each event "wedding" date is different for each participant. This method works for calculating age of participant at study start, which I have used successfully.

It should work, assuming you used two variables, please explain how it "doesn't work".

Re: Conflicting Ages Generated using INTCK

art297 — Wed, 10 Jan 2018 03:31:49 GMT

If you're on at least 9.3, I'd used the yrdif function. e.g.:

age=YRDIF(start-date,end-date);

There is a third parameter you can add, but age is the default for that parameter.

Art, CEO, AnalystFinder.com

Re: Conflicting Ages Generated using INTCK

Kurt_Bremser — Wed, 10 Jan 2018 08:38:25 GMT

@LAsasuser79 wrote:
This solution doesn't work because each event "wedding" date is different for each participant. This method works for calculating age of participant at study start, which I have used successfully.

It's time to post some example data in a data step. Right now we're fishing in the dark with respect to your data and have to make up things.

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Wed, 10 Jan 2018 12:05:24 GMT

HI Reeeza,

This code works for calculating age at study start, which is the same start date for all participants. The output gives me the age in years for each participant.

data want; set have;

today=MDY(12,01,2016);

days=today-BIRTH_DATE;

AGEtest= floor ((intck('month',BIRTH_DATE,today) - (day(today) < day(BIRTH_DATE))) / 12);*age at study start;

However, what I am trying to calculate is participant's age at first vaccination, which differs for each participant. Therefore, I can't plug in a date rage for the interval to check against in order to count age correctly.

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Wed, 10 Jan 2018 12:53:36 GMT

UPDATED with data lines:

Kurt,

See below.

I calculate age at study start (Age Test) and most importantly age at first vaccination(VAGE). The issue I'm running into is age at first vaccination as it gives me an age range of 0-18, which isn't true based on the age of my sample ( 7-21). I've attached the output for the code.

data Inas.hpvdata1; set Inas.hpvdata1;

today=MDY(12,01,2016);

days=today-BIRTH_DATE;

AGEtest= floor ((intck('month',BIRTH_DATE,today) - (day(today) < day(BIRTH_DATE))) / 12);*age at study start;

VAGE= INTCK('year',BIRTH_DATE,CHVaccDate_1,"Continuous");run; proc freq; table AGEtest VAGE;run;

proc freq; table AGEtest VAGE;run;

input CLIENT_ID BIRTH_DATE ddmmyy10. CHVaccDate_1 mmddyy10.;

data lines;

1, 08212000, 04062009

2,02232002, 04082011

3,05101999, 11222010

4,10191999, 03052012

Re: Conflicting Ages Generated using INTCK

Kurt_Bremser — Wed, 10 Jan 2018 12:36:08 GMT

Quote from myself:

"post some example data in a data step".

Don't expect us to type data from pictures.

And I only risked to open your Word document because I have LibreOffice at hand, which reduces the risk of malware somewhat. Many of the people here won't be able to access a docx because their firewalls block Office files.

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Wed, 10 Jan 2018 12:57:19 GMT

Noted. I've updated the post with a few data lines.

Re: Conflicting Ages Generated using INTCK

Kurt_Bremser — Wed, 10 Jan 2018 13:02:10 GMT

What are you trying to calculate here:

AGEtest= floor ((intck('month',BIRTH_DATE,today) - (day(today) < day(BIRTH_DATE))) / 12);*age at study start;

There is no variable today in your whole process, so it only yields missing values.

Re: Conflicting Ages Generated using INTCK

Kurt_Bremser — Wed, 10 Jan 2018 13:04:25 GMT

After playing around with it, I arrived at this code:

data have;
input CLIENT_ID BIRTH_DATE :mmddyy10. CHVaccDate_1 :mmddyy10.;
VAGE = INTCK('year',BIRTH_DATE,CHVaccDate_1,"Continuous");
format BIRTH_DATE CHVaccDate_1 mmddyy10.;
datalines; 
1 08212000 04062009
2 02032002 04082011
3 05101999 11222010
4 10191999 03052012
;
run;

proc freq;
table VAGE;
run;

Run this and see if it meets your expectations.

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Wed, 10 Jan 2018 13:30:43 GMT

Here I'm calculating the age of my sample at the start of the study. This code works to do that. I believe my value for today was included in the code I pasted.

Re: Conflicting Ages Generated using INTCK

LAsasuser79 — Wed, 10 Jan 2018 13:38:11 GMT

I did try this code earlier. My question was related to which of the INTCK code options will give the most accurate age, since they all slightly differed. I am going to use this option with the continuous option as the most valid response.

Re: Conflicting Ages Generated using INTCK

Kurt_Bremser — Wed, 10 Jan 2018 13:43:23 GMT

OK, saw it.

Run this:

data have;
input CLIENT_ID BIRTH_DATE :mmddyy10. CHVaccDate_1 :mmddyy10.;
today=MDY(12,01,2016);
AGEtest= floor ((intck('month',BIRTH_DATE,today) - (day(today) < day(BIRTH_DATE))) / 12);*age at study start;
agetest1 = intck('year',BIRTH_DATE,today,'c');
VAGE = INTCK('year',BIRTH_DATE,CHVaccDate_1,"Continuous");
format BIRTH_DATE CHVaccDate_1 mmddyy10.;
datalines; 
1 08212000 04062009
2 02032002 04082011
3 05101999 11222010
4 10191999 03052012
;
run;

proc freq;
table agetest agetest1 VAGE;
run;

At least for the set of test data, both calculations for agetest resolve to the same value, and vage also looks correct.