topic Re: Indicator for year of sale in SAS Programming

Indicator for year of sale

altijani — Thu, 21 Sep 2017 19:13:44 GMT

Hi Community

I have the following dataset:

ID year event

1 2014 0

1 2015 0

1 2016 1

2 2014 0

2 2015 1

2 2016 1

3 2014 1

3 2015 1

3 2016 1

I need to create an indicator that shows me the year the event happend, even for the years that the event was 0, as follows:

ID year event year_event

1 2014 0 2016

1 2015 0 2016

1 2016 1 2016

2 2014 0 2015

2 2015 1 2015

2 2016 1 2015

3 2014 1 2014

3 2015 1 2014

3 2016 1 2014

Any help is highly appreciated. Sorry if it is too simple.

Thanks!

Re: Indicator for year of sale

PaigeMiller — Thu, 21 Sep 2017 19:25:10 GMT

UNTESTED CODE

data first;
    set have;
    prev_event=lag(event);
    prev_id=lag(id);
    if id=prev_id and event=1 and prev_event=0 then output;
run;
data want;
    merge have first(rename=(year=year_event) drop=prev_event prev_id);
    by id;
run;

Assumes data is sorted by ID and year.

Re: Indicator for year of sale

ShrutiD — Fri, 22 Sep 2017 15:19:51 GMT

TESTED CODE:

data count(rename= Year=Year_event);
set records;
by ID;
if first.ID then count=0;
if event eq 1 then count+1;
if count eq 1 then output;
drop event;
run;

data result;
merge records count;
by ID;
drop count;
run;
proc print data=result;
run;

Re: Indicator for year of sale

Ksharp — Sat, 23 Sep 2017 12:52:11 GMT

data have;
input ID year event ;
cards;
1  2014  0
1  2015  0
1  2016  1
2  2014  0
2  2015  1
2  2016  1
3  2014  1
3  2015  1
3  2016  1
;
run;
data want;
 do until(last.id);
   set have;
   by id;
   if event and not found then do;new_year=year;found=1;end;
 end;
 do until(last.id);
   set have;
   by id;
   output;
 end;
 drop found;
run;