topic Re: Extracting the word before and after a specific index word in SAS Programming

Extracting the word before and after a specific index word

ammarhm — Thu, 13 Jul 2017 14:14:15 GMT

Hi I have a string from which i need to extract the word before and after a specific index word (trigger). The string looks like this word word word word word WORD_BEFORE trigger WORD_AFTER word word word word I can extract WORD_AFTER using the following code: WORD_AFTER = scan(substr(string,index(string,"trigger")),2); However, i cant seem to get the code right to extract the WORD_BEFORE, any suggestions please? Kind regards

Re: Extracting the word before and after a specific index word

RW9 — Thu, 13 Jul 2017 14:26:12 GMT

Note this assumes only one occurence of the word, otherwise you will get the last one:

data want;
  length before after $200;
  string="word word word word word WORD_BEFORE trigger WORD_AFTER word word word word";
  do i=1 to countw(string," ");
    if scan(string,i," ")="trigger" then do;
      before=scan(string,i-1," ");
      after=scan(string,i+1," ");
    end;
  end;
run;

Re: Extracting the word before and after a specific index word

art297 — Thu, 13 Jul 2017 14:40:20 GMT

Here is one way:

data have;
  informat string $80.;
  input string &;
  cards;
now is the time this must stop
Now hear this and do it quickly
;

data want;
  set have;
  WORD_BEFORE = scan(string,findw(string,"this",' ',"e")-1," ");
  WORD_AFTER = scan(string,findw(string,"this",' ',"e")+1," ");
run;

Art, CEO, AnalystFinder.com

Re: Extracting the word before and after a specific index word

kiranv_ — Thu, 13 Jul 2017 16:37:47 GMT

Another way

data have;
  string="word word word word word WORD_BEFORE trigger WORD_AFTER word word word word";
word_before=  prxchange('s/(.+)(WORD_BEFORE)(.+)/$2/', -1, string);
word_after=  prxchange('s/(.+)(WORD_AFTER)(.+)/$2/', -1, string);

run;

Re: Extracting the word before and after a specific index word

mkeintz — Thu, 13 Jul 2017 19:13:36 GMT

If the trigger value is not present then this code would generate word_before=last-word-of-string, and word_after=first-word-of-string, with no attendent NOTEs on the log.

And if the trigger appears as the first word, then word_before generates a note, Or if the word appears only as the last word, then word_after generates a note.

If these condition are to be avoided, I'd recommend a minor alteration of @art297's response:

data want (drop=ix);
  set have;
  ix=findw(string,"stop",' ','e');
  if ix>1              then WORD_BEFORE = scan(string,ix-1," ");
  if ix<countw(string) and ix^=0 then WORD_AFTER = scan(string,ix+1," ");
run;

Re: Extracting the word before and after a specific index word

DR_Jorg — Thu, 31 Jan 2019 17:32:32 GMT

Hi,

This is great! Thank you.

I am wondering how you would do this iteratively. I am trying to parse the word before a trigger word, but sometimes the trigger word appears more than once. I need to be able to pull it each time the trigger word appears. The word before is different every time, but the trigger is the same.

something like:

string="word word word word word WORD_BEFORE_1 trigger WORD_AFTER word word word word WORD_BEFORE_2 trigger WORD_AFTER WORD_BEFORE_3 trigger WORD_AFTER";

WORD_BEFORE_1=

WORD_BEFORE_2=

WORD_BEFORE_3=

etc.

Re: Extracting the word before and after a specific index word

RW9 — Fri, 01 Feb 2019 07:54:27 GMT

It is a good idea to start a new topic, provided test data and required output. This topic is closed, and over a year old. I would suggest a simple loop, i=1 to scan(your_string), and check each word within the loop.

Re: Extracting the word before and after a specific index word

DR_Jorg — Fri, 01 Feb 2019 13:55:37 GMT

Thanks, I posted it as a new topic here:

https://communities.sas.com/t5/New-SAS-User/Iteratively-extracting-the-word-before-a-specific-index-word/m-p/531982#M5952