topic Re: SAS_Count Frequency in SAS Programming

SAS_Count Frequency

Khaladdin — Sat, 01 Jul 2017 17:41:19 GMT

Hi all,

I want to ask a complicated (for me) question about SAS programming. I think I can explain better by using simple example. So, I have the following dataset:

Group Category

A 1

A 2

A 1

A 2

A 3

B 1

B 2

B 1

B 3

B 2

I want to count the each category for each group. I can do it by using PROC FREQ. But it is not better way for my dataset. It will be time consuming for me as my dataset is too large and I have a huge number of groups. So, if I use PROC FREQ, firstly I need to create new datasets for each group and then use PROC FREQ for each group. In sum, I need to create the following dataset:

Re: SAS_Count Frequency

Shmuel — Sat, 01 Jul 2017 18:26:46 GMT

You wrote that you have " a huge number of groups". How huge is it ?

Try to run:

proc freq data=have;
    table group*category / nopercent 
       out=want;
run;

Re: SAS_Count Frequency

Khaladdin — Sat, 01 Jul 2017 18:43:30 GMT

Thanks for reply. It is high frequency data. So, I have more than one million groups.

Re: SAS_Count Frequency

Shmuel — Sat, 01 Jul 2017 18:50:37 GMT

If it takes too much time or you are short with memory, add a sort:

proc sort data=have; by group; run;

proc freq data=have;
    by group;
    table group*category / nopercent 
       out=want;
run;

Re: SAS_Count Frequency

Khaladdin — Sat, 01 Jul 2017 18:53:28 GMT

Many thanks. I will try it tomorrow. I will let you know about the result. Many thanks agaib.

Re: SAS_Count Frequency

mkeintz — Sat, 01 Jul 2017 20:44:53 GMT

It appears to me that you want, for each group, to rank categories for each group.

Then produce one obs for each group with variables CAT1, CAT2, .... CATj. CAT1 will contain the most frequent category (what I think you mean by "first category"), CAT2 the second most frequent, through CATj (where J is the number of distinct categories in the group having the highest cardinatliy.

If your data are aleady sorted by group, it's two steps:

Use proc freq to generate a data set T1 of frequencies sorted by GROUP and then descending frequency ("order=freq") within group.
```
proc freq data=have noprint order=freq;
  by group;
  table category / out=t1;
run;
```
Then just use proc transpose to collapse the descending frequencies for each group into a single row with vars CAT1, CAT2, ...
```
proc transpose data=t1 out=want  prefix=CAT;
  by group;
  var category;
run;
```

Now if your data are NOT sorted, it's three steps - but don't worry - you don't have to sort the original data, just the frequencies:

(and 2) Get frequencies of group*category and sort by descending frequency within each group:

proc freq data=have noprint ;
  table group * category / out=t1;
run;
proc sort data=t1;
  by group descending count;
run;

(see above)

Now transpose a column to a row for each group.

proc transpose data=t1 prefix=CAT;
  by group;
  var category;
run;

Re: SAS_Count Frequency

Khaladdin — Sun, 02 Jul 2017 08:37:15 GMT

Frequency works. But, transpose does not work.

Re: SAS_Count Frequency

MikeZdeb — Sun, 02 Jul 2017 17:47:28 GMT

Hi, another idea (not 1 million groups, but 12 million observations ... SUMMARY + TRANSPOSE juts a few seconds). I don't see in your exmaple output the need to rank counts within groups.

data x;
input (group category) (:$1.) @@;
datalines;
A 1 A 1 A 2 A 1 A 2 A 3
B 1 B 2 B 2 B 1 B 3 B 2
;

data bigx;
set x;
do _n_=1 to 1e6;
output;
end;
run;

proc summary data=bigx nway;
class group category;
output out=y (drop=_type_);
run;

proc transpose data=y out=z (drop=_name_) prefix=cat;
by group;
var _freq_;
id category;
run;

DATA SET: z

group cat1 cat2 cat3

A 3000000 2000000 1000000
B 2000000 3000000 1000000

Re: SAS_Count Frequency

mkeintz — Thu, 06 Jul 2017 01:54:53 GMT

Show the log of the non-working code please.