topic Re: why you can't use a macro funcation like %scan inside of a data step in SAS Programming

why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 07:50:08 GMT

Hi I think this is a very basic question.

why I can't use %scan or some other macro function inside of a datastep.

Is this because data step is reading value from PDV and %scan is creating a text?

%let a=%str(a_b);

data a;

a= "'"||%scan(&a,2,_)||"'";

run;

I wonder why the above program won't work.

please provide detailed explaination and refer me to any document if it is relevant.

Thanks

Re: why you can't use a macro funcation like %scan inside of a data step

Peter_C — Wed, 17 May 2017 07:13:46 GMT

All about timing
Compile time : is macro time
Run time : observation time

Re: why you can't use a macro funcation like %scan inside of a data step

Kurt_Bremser — Wed, 17 May 2017 07:17:07 GMT

The macro processor is a pre-processor. Anytime the SAS interpreter encounters a macro trigger (& or %), it sends all text of the trigger to the macro processor. This then deals with it and returns (or not, ie if a %put just writes to the log) text to the SAS interpreter for further execution.

So all macro triggers are resolved before a data or procedure step starts to run.

Re: why you can't use a macro funcation like %scan inside of a data step

SASKiwi — Wed, 17 May 2017 07:21:51 GMT

As a general rule use %scan when you are writing macro code statements and use the SCAN function in SAS code. Believe me it's a lot easier that way and it works:

%let a=%str(a_b);
 
data a;
  a = scan("&a", 2, "_");
run;

Re: why you can't use a macro funcation like %scan inside of a data step

Astounding — Wed, 17 May 2017 07:22:07 GMT

It's partly what you mentioned (processing text vs. processing data in the PDV). But it's more than that. Macro language constructs your program. It doesn't process your data. Picture this stand-alone statement:

%let b = %scan(a,2,_);

Macro language would process the text "a", and would return a null string since there is no second word within the text "a".

In the context of your program, macro language does the same thing. It processes "a" before your DATA step begins to run, as part of the process of compiling the DATA step statements and determining what statements should become part of the DATA step. If you wanted macro language to return "b" instead (the second word within "a_b", you could get that with:

%let a = a_b;

%let b = %scan(&a,2,_);

But none of that processing takes place within a DATA step. All of it takes place as part of the compilation process that determines what statements the DATA step contains. So consider your original program:

%let a = a_b;

data a;

a= "'"||%scan(a,2,_)"'";

run;

%SCAN runs before the DATA step begins, and generates this program:

data a;

a= "'"||"'";

run;

The bottom line: macro language constructs a program. It doesn't process your data.

Re: why you can't use a macro funcation like %scan inside of a data step

Peter_C — Wed, 17 May 2017 07:40:25 GMT

Of course, there always exception to rules.
So the RESOLVE() data step function invokes the macro language environment processor to "resolve" the string parameter as if it is macro language syntax.
This use of the macro language provides a very different performance to the macro language processing which occurs in the usual way. This becomes most obvious when you think about doing the "resolve" on every data step iteration.... imagine a 100 million row table through a data step using RESOLVE()

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 07:46:25 GMT

I wonder why %scan below can't resolved to "b"

%let a = a_b;
data a;
a= "'"||%scan(a,2,_)"'";
run;

i thought %scan would be resolved to b before data step get executed.

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 07:51:03 GMT

Sorry I had a typo error . The code is fixed now.

thanks

Re: why you can't use a macro funcation like %scan inside of a data step

Peter_C — Wed, 17 May 2017 07:58:34 GMT

If you want to use macro variable A then it must be prefixed with &
Your code is referring to data variable A

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 07:59:34 GMT

Yeah I fixed the code now. But it still didn't work

Re: why you can't use a macro funcation like %scan inside of a data step

Astounding — Wed, 17 May 2017 08:02:06 GMT

Even in your fixed code, a means a. It's just a letter. It has no connection to any variable in any DATA step. Macro language doesn't require quotes for it to treat characters as text. That's the default interpretation: characters are text whether they have quotes around them or not.

Re: why you can't use a macro funcation like %scan inside of a data step

Peter_C — Wed, 17 May 2017 08:08:09 GMT

The base SAS language provides two stages for processing
1 deriving syntax (called macro language processing)
2 processing data in the data step iteration (or running a procedure like FREQ)
There is no need to make the functionality of one of these "stages", do both jobs.

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 08:09:17 GMT

I don't quite understand.

Doesn't %scan(&a,2,_) resolved to %scan(a_b,2,_) further resolved to b?

b with quotation should be treated as value?

Re: why you can't use a macro funcation like %scan inside of a data step

Peter_C — Wed, 17 May 2017 08:11:18 GMT

did you try

%let a = a_b;
data a;
a= "%scan(&a,2,_)" ;
run;

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 08:13:03 GMT

Yeah but the % inside of double quotation won't get processed properly.

Re: why you can't use a macro funcation like %scan inside of a data step

Kurt_Bremser — Wed, 17 May 2017 08:14:29 GMT

The ONE IMPORTANT question has not yet been asked: what are you trying to achieve? Do you want to parameterize the use of a data step variable in a data step, or do you want to parameterize a value in a data step?

Re: why you can't use a macro funcation like %scan inside of a data step

Astounding — Wed, 17 May 2017 08:14:50 GMT

In macro language, b is not a value. b is a letter that might be part of a SAS statement. For example, after generating b with the %SCAN function, you would have this statement:

%let a = a_b;

%let b = %scan(&a, 2, _);

The macro variable &b contains the letter b. But if it were part of this DATA step statement that would cause a problem:

%let a = a_b;

data a;
a= "'"||%scan(&a,2,_)"'";
run;

The DATA step statement would look like this:'

a = "'" ||b"'";

That's not a valid DATA step statement.

Re: why you can't use a macro funcation like %scan inside of a data step

Kurt_Bremser — Wed, 17 May 2017 08:19:46 GMT

@gyambqt wrote:

Yeah but the % inside of double quotation won't get processed properly.

Nonsense. Double quotes are exactly what's needed to resolve macro triggers:

%let a=%str(a_b); /* is equivalent to %let a=a_b; */

data a;
a = "%scan(&a,2,_)";
run;

proc print data=a;
run;

Dataset a contains the value "b" in variable a.

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 08:21:13 GMT

But if I didn't use the || to concanate quotation mark together around b , I believe the treat b as a variable rather than value.

but here I used || so the final resolved value should be a='b'..... am I wrong?

a= "'"||%scan(&a,2,_)||"'";

Re: why you can't use a macro funcation like %scan inside of a data step

gyambqt — Wed, 17 May 2017 08:26:30 GMT

Hmm is a="%scan(&a,2_)" equivlent to a= "'"||%scan(&a,2,_)||"'"