topic Re: Combinations of binary indicator in SAS Programming

Combinations of binary indicator

kaushik_patra — Mon, 10 Apr 2017 19:09:18 GMT

Hi everyone,

I would like to generate all possible combinations of three variables each with values 0 or 1 e.g. following using a data step

000

001

010

100

011

101

110

111

what will be a good way to do it?

Re: Combinations of binary indicator

ChrisHemedinger — Mon, 10 Apr 2017 19:21:35 GMT

Check out the ALLCOMB function in SAS. Designed just for such a thing!

Re: Combinations of binary indicator

Astounding — Mon, 10 Apr 2017 19:36:57 GMT

These combinations are just a sequence of binary numbers. You don't need any data to do that:

data want;

do i=0 to 7;

result = put(i, binary3.);

output;

end;

drop i;

run;

Re: Combinations of binary indicator

kaushik_patra — Mon, 10 Apr 2017 22:50:30 GMT

Thanks, it's a nice function. But the problem is I have n=2 (0 or 1) but k=3 which doesn't work for ALLCOMB.

Re: Combinations of binary indicator

kaushik_patra — Mon, 10 Apr 2017 23:03:29 GMT

Thanks, this is a nice little trick. I will have to have 3 different columns for all combinations of 0 or 1.

Re: Combinations of binary indicator

ballardw — Mon, 10 Apr 2017 23:06:41 GMT

A not terribly bright solution

data _null_;
    do i='0','1';
      do j='0','1';
         do k='0','1';
            comb=cats(i,j,k);
            put comb=;
         end;
      end;
   end;
run;

Re: Combinations of binary indicator

kaushik_patra — Mon, 10 Apr 2017 23:27:28 GMT

Thanks. The need is to have three distinct columns rather than a single column with all possible combinations.

Re: Combinations of binary indicator

Tom — Mon, 10 Apr 2017 23:35:14 GMT

For three it is simple.

data want;
  do a=0,1; do b=0,1; do c=0,1;
    output;
  end; end; end;
run;

Re: Combinations of binary indicator

kaushik_patra — Mon, 10 Apr 2017 23:49:28 GMT

Great! This has promise. If I have two arrays
P = (0 1) and x = (x1 x2 x3) where each of x takes values 0 or 1, how would you do it?

Re: Combinations of binary indicator

Tom — Tue, 11 Apr 2017 00:07:09 GMT

Not sure what you are talking about at this point. If you have four variables named P, X1 , X2, and X3 then you could build all combinations using similar DO loops. If you have two tables and want to join them to produce all possible combinations then PROC SQL does a good job.

proc sql ;
  create table want as
  select *
  from P, X
  ;
quit;

If you really have two vectors and what to manipulate them then use PROC IML. You can do lots of matrix manipulation using a language designed to work with matrices.

Re: Combinations of binary indicator

kaushik_patra — Tue, 11 Apr 2017 00:18:19 GMT

Thanks, I have the following data -
Data a;
Array p[2] (0 1);
Array x[3];
I would like the data step operations to produce 8 rows with the unique combinations.

Re: Combinations of binary indicator

Tom — Tue, 11 Apr 2017 03:22:36 GMT

So maybe something like this.

data want;
  array p[2] _temporary_ (0 1);
  array x[3];
  do _n_=0 to dim(p)**dim(x)-1;
     do i=1 to dim(x);
       x(i)=p(1+mod(int(_n_/(dim(p)**(i-1))),dim(p))) ;
     end;
     output;
  end;
  drop i ;
run;

Re: Combinations of binary indicator

kaushik_patra — Tue, 11 Apr 2017 01:37:19 GMT

This is cool. I have devised a similar solution (but less technical) based on Astounding's proposal.

data a;

array p[2] _temporary_;

array x[3];

do i=1 to dim(p)**dim(x);

result = put(i, binary3.);

do j=1 to 3;

x[j]=substr(result,j,1);

end;

output;

end;

drop i j;

run;