topic Re: How to split a data frame into 60% training, 20% validation, and 20% test sets? in SAS Programming

How to split a data frame into 60% training, 20% validation, and 20% test sets?

John4 — Sat, 18 Mar 2017 22:33:23 GMT

I'm using SAS to do machine learning. I would like to randomly split my data into 60% training, 20% validation, and 20% test data sets. How do I do that in SAS?

Re: How to split a data frame into 60% training, 20% validation, and 20% test sets?

art297 — Sat, 18 Mar 2017 23:07:57 GMT

There are many ways. Here is one:

data training validation test;
  set sashelp.class;
  _n_=rand('uniform');
  if _n_ le .6 then output training;
  else if _n_ le .8 then output validation;
  else output test;
run;

Art, CEO, AnalystFinder.com

Re: How to split a data frame into 60% training, 20% validation, and 20% test sets?

Reeza — Sat, 18 Mar 2017 23:26:18 GMT

Are you using SAS EM? If so, check the Partition task.

Re: How to split a data frame into 60% training, 20% validation, and 20% test sets?

John4 — Sun, 19 Mar 2017 01:59:42 GMT

No, i'am using SAS only

Re: How to split a data frame into 60% training, 20% validation, and 20% test sets?

Ksharp — Sun, 19 Mar 2017 02:48:36 GMT

Or PROC SURVEYSELECT.


%let dsid=%sysfunc(open(sashelp.class));
%let nobs=%sysfunc(attrn(&dsid,nlobs));
%let dsid=%sysfunc(close(&dsid));

%let train=%sysevalf(0.6*&nobs,int);
%let valid=%sysevalf(0.2*&nobs,int);
%let test=%eval(&nobs-&train-&valid);

%put &train &valid &test;

proc surveyselect data=sashelp.class group=(&train &valid &test) out=want;
run;

data train valid test;
 set want;
 select(groupid);
 when(1) output train;
 when(2) output valid;
 when(3) output test;
 otherwise;
 end;
run;