topic Re: Variable values in SAS Programming

Variable values

viollete — Wed, 29 Jul 2015 10:48:36 GMT

hi,

I have this kind of variable (from 3 observation only the first one has value):

DATE

12 Nov 2013

13 Nov 2013

14 Nov 2013

and I want to make it like this:

DATE

12 Nov 2013

13 Nov 2013

14 Nov 2013

Re: Variable values

RW9 — Wed, 29 Jul 2015 10:55:34 GMT

Hi,

data have;

a=1; date="12 Nov 2013"; output;

a=2; date=""; output;

a=3; date=""; output;

a=1; date="13 nov 2013"; output;

run;

data want (drop=old_date);

set have (rename=(date=old_date));

retain date;

if old_date ne "" then date=old_date;

run;

Re: Variable values

Steelers_In_DC — Wed, 29 Jul 2015 11:42:44 GMT

Do you have an id number of some kind? If so I'd make sure it was sorted like this, that'll make sure all of your dates are in the right place.:

data have;

infile cards dsd;

informat date date9.;

format date date9.;

input ID$ date;

cards;

1,12NOV2013

2,13NOV2013

3,14NOV2013

;

proc sort data=have;by id descending date;

data want;

set have;

by id descending date;

retain _date;

if first.id then _date = date;

if missing(date) then date = _date;

drop _:;

run;

Re: Variable values

viollete — Wed, 29 Jul 2015 11:56:25 GMT

I gave just very small part of my dataset, in overall i have hundreds of date observations (not just three) and i have more variables.

Re: Variable values

RW9 — Wed, 29 Jul 2015 12:01:19 GMT

I doesn't matter how many observations there are, the logic is the same:

- Step 1 - Sort the data into the order you require it.

- Step 2 - Loop over the dataset (datastep), and for each row identify if variable is missing and if so replace the missing with the retained value.

Re: Variable values

Astounding — Wed, 29 Jul 2015 22:48:37 GMT

Here's an approach that is quick and easy. However, note that it will affect missing values for ALL your variables, not just ones that you have in mind such as DATE:

data middle;

set have;

dummy='abc';

run;

data want (drop=dummy);

update middle (obs=0) middle;

by dummy;

output;

run;

Re: Variable values

Dalveer — Mon, 03 Aug 2015 06:37:56 GMT

check the below code ,this will work:

data have;

input DATE;

format date date9.;

informat date date9.;

cards;

12Nov2013

13Nov2013

14Nov2013

;

run;

data want(drop=i);

set have;

do i=0 to 2 ;

output;

end;

run;

Re: Variable values

EricHoogenboom — Mon, 03 Aug 2015 07:01:05 GMT

data filled (drop=_date);

set empty (rename=(date=_date));

retain date;

if _date NE . then date = _date;

run;

Hth, Eric

Re: Variable values

data_null__ — Mon, 03 Aug 2015 12:35:04 GMT

Astounding wrote:

Here's an approach that is quick and easy. However, note that it will affect missing values for ALL your variables, not just ones that you have in mind such as DATE:

When you have variable that you want want to LOCF then bring them in using a SET statement.

data have;
   input DATE1 $16.; 
   date2 = date1;
   if not missing(date1) then set sashelp.class point=_n_;
   output; 
   call missing(of _all_);
   cards; 
12 Nov 2013
 
 
13 Nov 2013
 
 
14 Nov 2013
;;;;
   run; 
proc print; 
   run; 
data middle / view=middle;
   set have;
   dummy='abc'; 
   run; 
data want;
   update middle(obs=0 keep=dummy) middle(keep=dummy date:);
   by dummy;
   set have(drop=date:);
   output; 
   drop dummy;
   run; 
proc print; 
   run;