topic Re: How to change the datetime format to mmddyy10. in a SAS data set in SAS Programming

How to change the datetime format to mmddyy10. in a SAS data set

amahamud77 — Tue, 20 Jan 2015 17:53:42 GMT

My sas dataset has this below date format, format $21 informat $21

Could any one help me easiest way to convert this to mmddyy10.?

Date

2002-01-10 00:00:00.0

2002-03-15 00:00:00.0

2002-04-23 00:00:00.0

Appreciate your help in advance.

Re: How to change the datetime format to mmddyy10. in a SAS data set

ballardw — Tue, 20 Jan 2015 18:44:30 GMT

Since you imported it as character, as shown by $21 informat, you have two basic choices:

Reimport the data with a method that allows you to force the import format or create a new variable to hold the data value

To add a date only variable:

data want;

set have;

SASdate = input(date,yymmdd10.);

format SASDate mmddyy10.;

run;

Re: How to change the datetime format to mmddyy10. in a SAS data set

PGStats — Tue, 20 Jan 2015 18:44:36 GMT

$21. is a CHARACTER format, NOT a datetime format. Datetime variables are numbers, not characters. To convert from your character represetation to a SAS datetime, use ANYDTDTM. informat, as follows:

data test;

input Date &:$21.;

realDatetime = input(date, anydtdtm.);

format realDateTime datetime21.;

datalines;

2002-01-10 00:00:00.0

2002-03-15 00:00:00.0

2002-04-23 00:00:00.0

;

proc print; run;

Re: How to change the datetime format to mmddyy10. in a SAS data set

amahamud77 — Tue, 20 Jan 2015 20:13:47 GMT

Thanks a lot! that worked for me. A

Re: How to change the datetime format to mmddyy10. in a SAS data set

Orsini — Tue, 20 Jan 2015 20:31:04 GMT

data have;

attrib

newdate length=8 format=mmddyy10.

;

infile datalines4;

input charvar $21.;

newdate = input(scan(charvar,1," "),yymmdd10.);

put _all_;

datalines4;

2002-01-10 00:00:00.0

2002-03-15 00:00:00.0

2002-04-23 00:00:00.0

;;;;

run;