topic convert first letter of a string to upper case without using propcase in SAS Programming

convert first letter of a string to upper case without using propcase

KrishnaChandra — Mon, 21 Jul 2014 06:34:38 GMT

Please can you tell me how can i convert the first letter of a sting to uppercase without using procase()

data h;

input name$;

cards;

krishna

jizin

gayathri

madhav

neerav

priya

run;

Re: convert first letter of a string to upper case without using propcase

Scott_Mitchell — Mon, 21 Jul 2014 07:01:04 GMT

DATA WANT;

SET HAVE;

NAME2 = UPCASE(SUBSTR(LEFT(NAME),1,1))||SUBSTR(LEFT(NAME),2);

RUN;

Re: convert first letter of a string to upper case without using propcase

KrishnaChandra — Mon, 21 Jul 2014 07:11:47 GMT

Thanks Scott_Mitchell

Re: convert first letter of a string to upper case without using propcase

RW9 — Mon, 21 Jul 2014 09:51:27 GMT

Just to note, you can modify a character in place, without have to concatenate data back together again, though you won't notice any time diff without lots of rows

data x;

attrib res format=$20.;

res="assfsa";

substr(res,1,1)=upcase(substr(res,1,1));

run;

Re: convert first letter of a string to upper case without using propcase

data_null__ — Mon, 21 Jul 2014 11:13:43 GMT

I wonder if using FIRST would make any difference

substr(res,1,1)=upcase(first(res));

Re: convert first letter of a string to upper case without using propcase

RW9 — Mon, 21 Jul 2014 12:03:05 GMT

Yes, excellent suggestion. A few runs of the below two steps shows first using about 0.08 seconds less than the substr (e.g. 0.23 vs 0.31).

data x;

attrib res format=$20.;

do i=1 to 2000000;

res="assfsa";

substr(res,1,1)=upcase(first(res));

end;

run;

data y;

attrib res format=$20.;

do i=1 to 2000000;

res="assfsa";

substr(res,1,1)=upcase(substr(res,1,1));

end;

run;

Re: convert first letter of a string to upper case without using propcase

Ksharp — Mon, 21 Jul 2014 13:07:38 GMT

Or try this one . You gotta love Peal Regular Expression .

data h;
input name$;
cards;
krishna
jizin
gayathri
madhav
neerav
priya
run;
data _null_;
set h;
name = prxchange("s/(\w+)/\u\L$1/i", -1, name);
put name=;
run;

Xia Keshan

Re: convert first letter of a string to upper case without using propcase

arpi — Fri, 23 Jun 2017 00:26:42 GMT

NameHard = upcase(first(Name)) || substr(Name,2,length(Name));

You need to get first letter in caps with upcase and first function

After that with substring function get the last letters with length function.

Re: convert first letter of a string to upper case without using propcase

VISHNU239 — Tue, 16 Jan 2018 05:32:47 GMT

can anyone please explain me the SUBSTR function in the code?Thank you.