topic Re: Delete all datasets observations in a specific library in SAS Programming

Delete all datasets observations in a specific library

mohamed_zaki — Thu, 16 Oct 2014 11:29:29 GMT

How to delete every observation in each dataset in a specific lib.

PROC DELETE delete all the data set, what i need is to delete all the data set observations not the data sets it self.

Re: Delete all datasets observations in a specific library

data_null__ — Thu, 16 Oct 2014 12:15:23 GMT

data class1 class2;
   set sashelp.class;
   run; 

*Keep the data set but delete the obs;
data class1;
   modify class1;
   remove; 
   run; 
proc contents data=class1;
   *reports 0 obs and 19 deleted obs;
   run; 



*Create the data set new with 0 obs;
data class2;
   stop; 
   set class2;
   run; 
proc contents data=class2;
   *reports 0 obs and 0 deleted obs;
   run; 

Re: Delete all datasets observations in a specific library

Ksharp — Thu, 16 Oct 2014 12:16:03 GMT

Here are two ways :

data class;

set sashelp.class;

stop;

run;

proc sql;

create table class like sashelp.class ;

quit;

Xia Keshan

Re: Delete all datasets observations in a specific library

mohamed_zaki — Thu, 16 Oct 2014 12:21:33 GMT

What if the data sets have different names not a series like class1 , class2 ......

and i do not know there names in advance_ the data sets i mean_, all what i know is the lib name

Re: Delete all datasets observations in a specific library

Kurt_Bremser — Thu, 16 Oct 2014 12:52:05 GMT

You can get the table names from sashelp.vmember.

Re: Delete all datasets observations in a specific library

Ksharp — Thu, 16 Oct 2014 13:12:59 GMT

Sure .Easy.

data class;set sashelp.class;run;
data cars;set sashelp.cars;run;

data _null_;
 set sashelp.vmember(where=(libname='WORK' and memtype='DATA')) end=last;
 if _n_ eq 1 then call execute('proc sql;');
 call execute(cat('create table _',trim(memname),' like ',trim(memname),';'));
 if last then call execute('quit;');
run;

Xia Keshan

Re: Delete all datasets observations in a specific library

JLlano — Sat, 19 Aug 2017 00:02:26 GMT

Sorry, but I can´t agree.

Both solutions create a new table with the structure of another one.

This code does delete records from a data set:

Data Lib.Table;

Set Lib.Table;

Stop;

run;

Similar but not the same;

Regards