topic How to show response option if it is a '0' in SAS Programming

How to show response option if it is a '0'

GregBond — Mon, 24 Mar 2014 18:55:49 GMT

I have data from a survey and would like the response options which ended up having a 0 count to be shown in the tables I made in proc freq.

Seems like a simple problem to fix, but i have yet to find a solution.

Thanks!

Re: How to show response option if it is a '0'

Reeza — Mon, 24 Mar 2014 19:18:51 GMT

If it appears in other fields you can try the sparse option.

proc freq data=have;

table question*answer/sparse;

run;

If it doesn't appear anywhere in your data you'll need to use proc tabulate or a different proc with the the preloadfmt option.

Re: How to show response option if it is a '0'

ballardw — Mon, 24 Mar 2014 21:31:55 GMT

I would recommend using 1) custom formats and 2) Proc Tabulate, Means or Report with the Preloadfmt option

proc format library=work;
value yndr
1='Yes'
2='No'
7="Don't Know"
9="Refused";
run;
data junk;
   do i = 1 to 5; x=1;output;end;
   do i = 1 to 3; x=2;output;end;
   do i = 1 to 4; x=7;output;end;
run;

proc tabulate data=junk;
   class x / preloadfmt missing;
   format x yndr.;
   table x, n='Count'
         /printmiss misstext='0';
run;

The misstext to show the zero for a missing count, otherwise it will display your current default for missing values.