topic Re: Create new observation from 'or' statement in SAS Programming

Create new observation from 'or' statement

TJ87 — Fri, 20 Jun 2014 22:39:38 GMT

Here's a scenario:

data have;

input id x $;

cards;

1 a

2 b

3 a or b

;

run

data want;

input id x $;

cards;

1 a

2 b

3 a

3 b

;

run;

Could someone please suggest code to get 'data want' from 'data have'? Thanks.

Re: Create new observation from 'or' statement

RichardinOz — Sat, 21 Jun 2014 08:01:05 GMT

Here is a one step solution

data have;

Infile cards missover ;

input id x $ @ ;

output ;

input @'or' x ;

If not missing(x) then output ;

cards;

1 a

2 b

3 a or b

;

run ;

Richard

Re: Create new observation from 'or' statement

Ksharp — Sat, 21 Jun 2014 09:30:58 GMT

data have;
  input id x $10.;
  cards;
1  a
2  b
3  a or b
;
run;
data want(drop=i x);
 set have;
 length y $ 10;
 do i=1 to countw(x);
  y=scan(x,i);
  if y ne 'or' then output;
 end;
run;

Xia Keshan

Re: Create new observation from 'or' statement

stat_sas — Sun, 22 Jun 2014 01:05:00 GMT

data want(drop= i x rename=(y=x));

set have;

i=1;

do while (scan(x,i,'or ') ne ' ');

id=_n_;

y=scan(x,i,'or ');

output;

i=i+1;

end;

run;