topic select column by position in SAS Programming

select column by position

Steelers_In_DC — Fri, 25 Jul 2014 19:59:14 GMT

It doesn't matter if using infile/input, proc sql or a data step. I am interested in selecting a column by it's position and renaming it. I will have a SAS dataset where the column names might change, one is only 2*3, very small but I have to reference it and cannot bet on the variable names being constant going forward. Any way to select the variable names by ordinal position and rename them?

Thanks,

Mark

Re: select column by position

data_null__ — Fri, 25 Jul 2014 21:31:01 GMT

In a data step you can define an ARRAY and reference the columns by their index. Say you want to work with numeric column number 3.

data reference;
   set sashelp.heart;
   array _n 
_numeric_; 
   * Reference to numeric column 3;
   if _n[3] lt 50; 
   run;

Re: select column by position

data_null__ — Fri, 25 Jul 2014 21:39:17 GMT

Or you can rename all the variable using their column index.

data heart;
   set sashelp.heart(obs=10);
   run; 

proc transpose data=heart(obs=0 /*keep=_numeric_*/) out=vars;
   var _all_;
   run; 
filename FT76F001 temp; 
data _null_; 
   file FT76F001;
   set vars;
   put 'Rename ' _name_ '=Col' _n_ ';'; 
   run; 

proc datasets; 
   modify heart;
   %inc FT76F001;
   run; 
   quit; 
proc print data=heart;
   run;