topic Insert a Row at the end of the data with totals in SAS Programming

Insert a Row at the end of the data with totals

MilenkoAndreas — Fri, 23 Jan 2015 20:20:40 GMT

Hello everyone! Is there any way to insert a row at the end of the data set with the totals? Here it is a sample data:

DATA	COUNT
DATA 1	23
DATA 2	35
DATA 3	27
DATA 4	24
DATA 5	25
DATA 6	22
DATA 7	29

And here it is what I want to do:

DATA	COUNT
DATA 1	23
DATA 2	35
DATA 3	27
DATA 4	24
DATA 5	25
DATA 6	22
DATA 7	29
Total	185

I will appreciate any kind of help!

Greetings,

Milenko

Re: Insert a Row at the end of the data with totals

Haikuo — Fri, 23 Jan 2015 20:40:12 GMT

One example:

data have;

input var $ COUNT;

cards;

DATA1 23

DATA2 35

DATA3 27

DATA4 24

DATA5 25

DATA6 22

DATA7 29

;

data want;

set have end=last;

_ct+count;

output;

if last then

do;

var='Total';

Count=_CT;

output;

end;

drop _ct;

run;

Re: Insert a Row at the end of the data with totals

slchen — Fri, 23 Jan 2015 20:56:19 GMT

data want;

set have;

run;

proc sql;

insert into want

select Ttotal' as data,sum(count) as count from have;

quit;

Re: Insert a Row at the end of the data with totals

Tom — Fri, 23 Jan 2015 23:10:34 GMT

Why?

If it is just for a report then just have the report generate the totals.

PROC PRINT ...;

VAR DATA COUNT ;

SUM COUNT;

RUN:

You can use PROC SUMMARY (means) to generate totals and PROC APPEND to attach to an existing file.

data class;

set sashelp.class ;

run;

proc means noprint data=class ;

output out=summary sum=;

run;

proc append data=summary base=class force;

run;

proc print data=class ;

run;

Re: Insert a Row at the end of the data with totals

Cynthia_sas — Sat, 24 Jan 2015 02:19:31 GMT

HI:
I would use PROC REPORT or PROC PRINT for a report like this. For example, using PROC REPORT, see a similar example using SASHELP.CLASS (where I add up the HEIGHT and WEIGHT instead of COUNT).

Cynthia

ods html file='c:\temp\Total_Line.html';

title 'Total Line for Students Heights';
proc report data=sashelp.class nowd
style(summary)=Header;
title 'Proc REPORT';
column name age sex height weight;
define name / order;
define age / order;
define sex / display;
define height/ sum;
define weight / sum;
rbreak after / summarize;
compute after ;
name='Total';
endcomp;
run;

ods _all_ close;

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 13:12:22 GMT

slchen! Thank you for your answer! Im new in using SAS, and I know very little, I tried your code, and it didnt work...it says that the Ttotal, sum columns dont exist, and that the sum functions needs a numeric value. Here it is the code that Im using:

data WORK.FILA_FINAL_COUNT;

set WORK.query_for_query_final;

run;

proc sql;

insert into WORK.FILA_FINAL_COUNT

select Ttotal as data,sum(C) as count from WORK.query_for_query_final;

quit;

It would be great if you could tell me what Im doing worng.

Greetings, and thanks again!

Milenko

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 13:15:52 GMT

Hai.Kuo! Thank you very much for your answer. Im new in using SAS, so i dont understand very well the code that you are giving me. I foyu could walk me a bit, it would great! I do know what you mean with data want and data have, but the rest is not really understandable for my level of knowledge, which is pretty basic. In any case, I really appreciate for your help!

Greetings!

Milenko

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 13:18:08 GMT

Tom! Thank you very much! But I dont want to do a report, I want create another data set. I want to create another data set, and i will keep working with it, applying functions, etc.In any case, I really appreciate your help.!

Greetings!

Milenko

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 13:19:28 GMT

Cynthia! Thank you so much! But I dont need to do a report. I want to create another data set, and I will keep working with it, applying functions, etc.In any case, I really appreciate your help.!

Greetings!

Milenko

Re: Insert a Row at the end of the data with totals

Tom — Wed, 30 Aug 2017 16:41:04 GMT

Editor's Note: Thanks everyone for all of the answers. The SQL one works well. This solution gives a little more flexibility for the number of variables that need to be summed and inserting text for the summary row.

Using PROC SUMMARY to generate the total row is the most "SAS like" way to do it.

If you want to put the string "TOTAL" into one of your character variables so that you can tell which row is the total and which rows are the real data then you would need to add some extra code.

For example if we assume that SASHELP.CLASS is your input data then these two steps will generate a new dataset named WANT with the totals appended.

proc means noprint data=sashelp.class ;

output out=summary sum=;

run;

data want ;

set sashelp.class summary (in=in2);

if in2 then name='TOTAL';

run;

Re: Insert a Row at the end of the data with totals

RW9 — Mon, 26 Jan 2015 13:36:41 GMT

Hi,

data have;
data="data1"; c=2; output;
data="data2"; c=2; output;
data="data3"; c=1; output;
run;

proc sql;
create table WANT as
select *
from    HAVE
union all
select "Total",
          sum(C) as C
from    HAVE;
quit;

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 14:16:22 GMT

Hey Tom! Thank you so much again! It is really helpful! I tried your code and it worked! But im almost there. The result that I get is this:

DATA	COUNT	_TYPE_	_FREQ_	name
DATA 1	23
DATA 2	35
DATA 3	27
DATA 4	24
DATA 5	25
DATA 6	22
DATA 7	29
-	185	0	7	Total

And the result that Im looking foward is this:

DATA	COUNT
DATA 1	23
DATA 2	35
DATA 3	27
DATA 4	24
DATA 5	25
DATA 6	22
DATA 7	29
Total	185

Is there a way to tweak your code to make it happen?

In any case you already have helped me a lot! Thank you!

Greetings!

Milenko

Re: Insert a Row at the end of the data with totals

Tom — Mon, 26 Jan 2015 14:32:22 GMT

The extra variables _TYPE_ and _FREQ_ are generated by PROC MEANS. You can remove them with a DROP statement.

The extra variable NAME is because you did not adjust the program to match the variables in your dataset. From your output you want to assign 'Total' to the variable DATA instead of the variable NAME.

Re: Insert a Row at the end of the data with totals

slchen — Mon, 26 Jan 2015 14:35:48 GMT

Sorry to miss a double quote for "Total";

data WORK.FILA_FINAL_COUNT;

set WORK.query_for_query_final;

run;

proc sql;

insert into WORK.FILA_FINAL_COUNT

select "Total" as data,sum(C) as count from WORK.query_for_query_final;

quit;

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 14:55:14 GMT

slchen, Thank you again! I tried the code and it still has problems with the C parameter:

ERROR: The SUM summary function requires a numeric argument.

ERROR: The following columns were not found in the contributing tables: C

Could you help me with this error, please!

Greetings!

Milenko

Re: Insert a Row at the end of the data with totals

slchen — Mon, 26 Jan 2015 15:04:27 GMT

data WORK.FILA_FINAL_COUNT;

set WORK.query_for_query_final;

run;

proc sql;

insert into WORK.FILA_FINAL_COUNT

select "Total" as data,sum(count) as count from WORK.query_for_query_final;

quit;

Re: Insert a Row at the end of the data with totals

yeshwanth — Mon, 26 Jan 2015 15:21:31 GMT

One simple approach:

data y1;
input data $ count;
cards;
d1 100
d2 500
d3 800
d4 60
;
quit;

proc sql;
create table y2 as
select "total" as data, sum(count) as count
from y1;
quit;

data final;
set y1 y2;
run;

Hope this helps !!

Re: Insert a Row at the end of the data with totals

art297 — Mon, 26 Jan 2015 15:30:31 GMT

Milenko,

This is in response to the question you asked . His code, with explanations, is shown below. The explanations are shown within comments, so that they don't have to be removed in order for the program to run:

data want;

set have end=last; /*use have to create new file called want and creating an extra temporary variable

called 'end' that will only have a value of 1 when the last record from have is read */

_ct+count; /*create a variable called _c1 that, by the time the last record is read, will contain the sum of

all values of count*/

output; /* output the record */

if last then do; /*ONLY do the following after the last record has been output */

var='Total'; /*Change the value of var to be Total*/

Count=_CT; /* Change the value of Count to equal the value of _CT */

output; /* Output the Total record */

end;

drop _ct; /* Drop _ct from the list of variables that will be output */

run;

Re: Insert a Row at the end of the data with totals

Haikuo — Mon, 26 Jan 2015 15:36:47 GMT

Thanks, Art! And my apologize to OP. I haven't realized being asked a follow-up question until Art mentioned my name. The bottom line is that there is no way for me to do a better job than Art anyway , so OP, consider yourself lucky.

Re: Insert a Row at the end of the data with totals

MilenkoAndreas — Mon, 26 Jan 2015 18:07:09 GMT

It worked perfectly! Thank you so much slchen!

Greetings!

Milenko