topic Re: Diagonal as horizontal in SAS Programming

Diagonal as horizontal

thod — Wed, 23 Oct 2013 11:41:05 GMT

Hi, I want to list the diagonal horizontal. Any suggestions? I dont have IML.

Re: Diagonal as horizontal

AncaTilea — Wed, 23 Oct 2013 11:43:54 GMT

Do you mean data that looks like this:

1 . . . .

. 2 . . .

. . 3. . .

. . . 4 .

. . . . 5

To look like this:

Re: Diagonal as horizontal

thod — Wed, 23 Oct 2013 12:02:49 GMT

Hi,

Yes, or like this:

1 2 3 4 5

Re: Diagonal as horizontal

AncaTilea — Wed, 23 Oct 2013 12:08:52 GMT

So you coukd do this:

data have;

input var1 var2 var3 var4 var5;

datalines;

1 . . . .

. 2 . . .

. . 3. . .

. . . 4 .

. . . . 5

;

data want;

set have;

var_want = max(of var1--var5);

run;

proc transpose data = want out = want_tran;var var_want;run;

But this is assuming that you have missing on the non-diagonal values.

Re: Diagonal as horizontal

thod — Wed, 23 Oct 2013 12:23:13 GMT

Hi Anca,

Tx, with a little adjustments it Works to my needs.

Made my day.

thod

Re: Diagonal as horizontal

thod — Wed, 23 Oct 2013 13:04:55 GMT

Hi Again,

Any solution if the non-diagonal values not are missing?

thod

Re: Diagonal as horizontal

AncaTilea — Wed, 23 Oct 2013 13:43:28 GMT

So IML would probably be desired for this.

Otherwise, you will need some sort of array to pass through and somehow tell SAS you want the column+1....

Yeah, I don't know.

Anca.

Re: Diagonal as horizontal

art297 — Wed, 23 Oct 2013 14:00:28 GMT

You could just use an array. e.g.:

data have;

input var1 var2 var3 var4 var5;

datalines;

1 . . . .

. 2 . . .

. . 3. . .

. . . 4 .

. . . . 5

;

data want (keep=var_want);

set have;

array all _all_;

var_want = all(_n_);

run;

Re: Diagonal as horizontal

snoopy369 — Wed, 23 Oct 2013 14:11:27 GMT

Similarly to Art's solution, but horizontal - using a temporary (and automatically retained) array to store the values and then copy back to the PDV in the last row.

data have;

input var1 var2 var3 var4 var5;

datalines;

1 . . . .

. 2 . . .

. . 3. . .

. . . 4 .

. . . . 5

;

data want;

set have end=eof;

array all _all_;

array temps [9999] _temporary_;

temps[_n_]=all[_n_];

if eof then do;

do _t = 1 to dim(all);

all[_t]=temps[_t];

end;

output;

end;

run;

Re: Diagonal as horizontal

thod — Thu, 24 Oct 2013 08:40:09 GMT

Hi Snoopy369,

Thanx for the answer. Do you also have a solution if I want tje diagonals below this one?

thod

Re: Diagonal as horizontal

snoopy369 — Thu, 24 Oct 2013 14:01:08 GMT

I don't know that "below this one" means, perhaps my math education is lacking. I only know of using 'diagonal' to mean the primary diagonal, either top left to bottom right or top right to bottom left. If you want something else, please explain.

Re: Diagonal as horizontal

Haikuo — Thu, 24 Oct 2013 14:30:36 GMT

Ok, here is a possible one for horizontal, credit to Data_null_;

data have;

input var1 var2 var3 var4 var5;

retain id 1;

datalines;

1 . . . .

. 2 . . .

. . 3. . .

. . . 4 .

. . . . 5

;

data want;

update have(obs=0) have;

by id;

drop id;

run;

Haikuo