topic Re: heteroscedastic variances in SAS Programming

heteroscedastic variances

dessert_fox — Sun, 24 Feb 2013 03:45:04 GMT

Does anyone know of a SAS code to generate heteroscedastic variances for two groups (i.e., treatment vs. control)?

Re: heteroscedastic variances

Reeza — Mon, 25 Feb 2013 15:49:02 GMT

I think we need more information on what you're looking for.

Re: heteroscedastic variances

PGStats — Mon, 25 Feb 2013 17:58:55 GMT

Do you want to simulate, estimate or compare variances for two groups? - PG

Re: heteroscedastic variances

dessert_fox — Mon, 04 Mar 2013 03:46:51 GMT

Yes, I wanted to simulate where the treatment group has a greater variance compared to the control group. Any model could do: t-test, ANOVA, or better yet a multilvel model.

Thanks,

Re: heteroscedastic variances

dessert_fox — Mon, 04 Mar 2013 03:49:40 GMT

Sorry I did not provide that much information to my earlier question. So basically, I want to simulate data where I can estimate and compare the variance between two groups (i.e., treatment vs. control) and it could be a simple t test, or ANOVA, or a multilevel model.

Thanks Reeza!

Rommel

Re: heteroscedastic variances

Saszealot — Mon, 04 Mar 2013 04:39:34 GMT

You should be looking at contrast or estimate statements with hovtest= bf welch lavene .

These options will give you different variance tests. A good book with examples is analysis of messy data volume 1 by milliken and johnson.

Re: heteroscedastic variances

PGStats — Mon, 04 Mar 2013 17:27:04 GMT

OK, here is a simulation of ANOVA with two groups, in the equal and unequal variances cases :

data test;
length case $16;
call streaminit(384239);
case = "EQUAL VARIANCES";
do group = "A", "B";
     do _n_ = 1 to 50;
          x = rand("NORMAL", 10, 2);
          output;
          end;
     end;
case = "UNEQUAL VARIANCES";
group = "A";
do _n_ = 1 to 50;
     x = rand("NORMAL", 10, 2);
     output;
     end;
group = "B";
do _n_ = 1 to 50;
     x = rand("NORMAL", 10, 3);
     output;
     end;
run;

proc glm data=test;
by case;
class group;
model x = group;
means group / hovtest welch;
run;

Re: heteroscedastic variances

dessert_fox — Tue, 05 Mar 2013 01:03:02 GMT

PG,

Thanks so much. This would give me a good starting point to learn how to simulate.

Rommel

Re: heteroscedastic variances

dessert_fox — Wed, 06 Mar 2013 23:13:12 GMT

PGStats,

I've strated writing simulation codes for multilevel mediation model for normal and non-normal combined with heteroscedastic variance. Would you be kind enough to take a look at my codes when you happen to have time?

Thanks so much for the help.

Rommel

Re: heteroscedastic variances

SteveDenham — Thu, 07 Mar 2013 13:08:12 GMT

Rommel,

Do you have SAS/IML licensed? If so, then take a look through 's blog, and find a wealth of information regarding simulation, with special parts on simulating from multivariable normal distributions, and correlated/clustered observations. IML is so much more powerful for simulation than DATA step programming that if simulation is going to be a major part of your work, you should consider getting a license.

Steve Denham

Re: heteroscedastic variances

dessert_fox — Fri, 08 Mar 2013 01:59:55 GMT

Yes Steve I have a SAS-IML license. And I have already looked through Rick Wicklin's blog and it's been very helpful. But right I would say I'm still at the very basic level of doing simulation. I wonder if at this point it's already ok to learn simulation in SAS-IML. I never knew it was more powerful though. But yes, I will start learnin SAS-IML. In fact, I already pre-ordered his book on simulation.

I really appreciate your advice.

Thanks Steve!

Rommel

Re: heteroscedastic variances

sirerwin — Thu, 26 Sep 2013 22:54:53 GMT

Thanks so much PG. One more question if you don't mind, do you have a sample simulation code to generate multilevel data?

Re: heteroscedastic variances

PGStats — Fri, 27 Sep 2013 00:55:29 GMT

Please be more precise. What would you like that data to look like?

Re: heteroscedastic variances

sirerwin — Sat, 28 Sep 2013 05:44:06 GMT

Specifically, I want to generate a multilevel data where I have a treatment and a control group with the following

conditions:

a) two levels of clusters (20 and 40 groups)

b) two levels of sample size (10 for small sample and 20 for medium-sized sample)

c) for each sample size, 1/2 is assigned to treatment and 1/2 is to control

Given these, I want to generate data from a nonnormal distribution (chi-square dist with df=1) and a

heteroscedastic variance where treatment to control variance ratio is 8:1.

From there I want to assess how nonnormality and heteroscedasticity affects the power and type I error of a statistical test.

Thanks so much, PG! Let me know if you need more details.

Re: heteroscedastic variances

plf515 — Sat, 28 Sep 2013 11:04:46 GMT

Rick's book on simulation is excellent (not surprising) and starts with the very basics.

Re: heteroscedastic variances

PGStats — Sat, 28 Sep 2013 21:50:47 GMT

One more detail. The chi-square distribution with ν degrees of freedom has mean = ν and variance = 2ν. Do you want your treatment and control groups to be simulated with different DFs, in which case they will have different means AND different variances?

Re: heteroscedastic variances

sirerwin — Sun, 29 Sep 2013 00:14:41 GMT

I want a chi-square distribution with 1 df (to reflect a severe nonnormality) and a heteroscedastic variance ratio of 8:1 between the treatment and control. I also want to have equal dfs for both treatment and control (balanced design). Hope this makes sense.

Thanks a lot, PG!!!

Re: heteroscedastic variances

PGStats — Sun, 29 Sep 2013 02:55:12 GMT

Do you mean that control and treatment samples should have the same mean but 1:8 variances? I think you need a related but slightly more general distribution to do that: the Gamma. Gamma(alpha, beta) has mean=alpha*beta and variance=alpha*beta**2.

As an introduction, here is how to generate an illustration of Gamma(1,1) and Gamma(0.125,8) (same mean, 1:8 variances)

data gamma;

do x = 0.1 to 10 by 0.1;
     y1 = PDF("GAMMA", x, 1, 1);
     y2 = PDF("GAMMA", x, 0.125, 8);
     output;
     end;
run;

proc sgplot data=gamma;
series x=x y=y1;
series x=x y=y2;
run;

Here is how to simulate data groups from those distributions and look at the resulting sample distributions:

data test;
call streaminit(875665);
do clustNb = 20, 40;
     do clustNo = 1 to clustNb;
          do sampSize= 10, 20;
               group="Treatment";

               do i = 1 to int(sampSize/2);
                    x = 8 * RAND("GAMMA", 0.125);
                    output;
                    end;
               group="Control";
               do i = int(sampSize/2)+1 to sampSize;
                    x = 1 * RAND("GAMMA", 1);
                    output;
                    end;
               end;
          end;
     end;
run;

proc univariate data=test;
class group;
var x;
histogram;
run;