topic Re: Data step-Max Function in SAS Programming

Data step-Max Function

rnmishra — Wed, 12 Dec 2012 02:14:18 GMT

A data set is given below.

Name Age

Jack 10

Joe 31

Tom 22

Roe 33

Rex 44

Tim 24

In a single step I am trying to find the person with maximum age from the individuals named Tom , Row and Joe.

Thanks

Re: Data step-Max Function

art297 — Wed, 12 Dec 2012 03:42:06 GMT

Sounds like a homework assignment. Try to solve it and, if you run into a problem, post your attempted code.

Re: Data step-Max Function

rnmishra — Wed, 12 Dec 2012 17:47:18 GMT

Will be doing something like this for my project coming soon. Looking at my data, I am trying to figure out the candidate codes.

This works.

But I want to do this in a single step, these are my trails,

Thanks.

Re: Data step-Max Function

PGStats — Wed, 12 Dec 2012 18:00:47 GMT

Your second attempt should have worked.

Re: Data step-Max Function

Haikuo — Wed, 12 Dec 2012 18:13:53 GMT

You don't have to involve Macro variables, because if you do, it generally means more than ONE steps.

data have;

input Name $ Age;

cards;

Jack 10

Joe 31

Tom 22

Roe 33

Rex 44

Tim 24

;

/*OEN STEP SQL*/

proc sql;

select * from have where upcase(name) in ('TOM','ROE','JOE') HAVING AGE=MAX(AGE);

QUIT;

/*ONE STEP DATASTEP*/

DATA WANT;

SET HAVE (WHERE=(UPCASE(NAME) IN ('TOM','ROE','JOE'))) END=LAST;

LENGTH _N $20.;

RETAIN _N _A;

IF _A<AGE THEN DO; _A=AGE; _N=NAME;END;

IF LAST THEN DO; AGE=_A;NAME=_N;OUTPUT;END;

DROP _:;

RUN;

Haikuo

Re: Data step-Max Function

art297 — Wed, 12 Dec 2012 18:14:27 GMT

Your final datastep doesn't include a set statement so, minimally, it doesn't know what 'name' is and/or have any values to compare.

Re: Data step-Max Function

Tom — Wed, 12 Dec 2012 18:22:25 GMT

The data step does not understand the aggregation functions of SQL. There is a separate MAX() function that will find the maximum from a list of values one the current observation only. For example: max(var1,var2,var3,var4)

To summarize across rows use PROC SUMMARY.

Re: Data step-Max Function

Linlin — Wed, 12 Dec 2012 18:31:41 GMT

Hi,

try the code below:

data have;

input Name$ Age;

cards;

Jack 10

Joe 31

Tom 22

Roe 100

Rex 44

Tim 24

;

data _null_;

retain max_age 0;

set have (where=( upcase(name)in('TOM','ROE','REX')));

max_age=ifn(age>max_age,age,max_age);

call symputx('max_age',max_age);

run;

%put &max_age;

Re: Data step-Max Function

Linlin — Wed, 12 Dec 2012 18:40:57 GMT

or improved version:

data _null_;

retain max_age 0;

set have (where=( upcase(name)in('TOM','ROE','REX'))) end=last;

max_age=ifn(age>max_age,age,max_age);

if last then call symputx('m_age',max_age);

run;

%put &m_age;

Re: Data step-Max Function

Astounding — Wed, 12 Dec 2012 18:54:19 GMT

I like Hai.kuo's SQL solution. But if you must have a one-step DATA step solution as well, here's one:

data want;

do until (done1);

set have end=done1;

where name in ('Tom', 'Roe', 'Rex');

max_age = max(age, max_age);

end;

do until (done2);

set have end=done2;

where name in ('Tom', 'Roe', 'Rex');

if age = max_age then output;

end;

run;