Return Data Classes Even If No Records?

FarazA_Qureshi — Sat, 14 Sep 2013 08:01:25 GMT

While PROC FORMAT helps in dividing dataset in desired categories with PUT() as:

PROC FORMAT;

value Buckets

low -< 1 = 'Bucket 1'

1 -< 30 = 'Bucket 2'

30 -< 60 = 'Bucket 3'

60 -< 90 = 'Bucket 4'

90 -< 120 = 'Bucket 5'

120 -< 150 = 'Bucket 6'

150 -< 180 = 'Bucket 7'

180 -< 210 = 'Bucket 8'

210 -< 240 = 'Bucket 9'

240 -< 270 = 'Bucket 10'

270 -< 300 = 'Bucket 11'

300 -< 330 = 'Bucket 12'

330 -< 360 = 'Bucket 13'

360 - High = 'Bucket 14'

;

run;

Could a dataset be returned to represent all the buckets declared above even no entry exists in the same. Something like:

Bucket 1	3615833
Bucket 2	11899480
Bucket 3	.
Bucket 4	1340713
Bucket 5	2618488
Bucket 6	.
Bucket 7	8479480
Bucket 8	11619361
Bucket 9	.
Bucket 10	8103834
Bucket 11	11894685
Bucket 12	.
Bucket 13	300642
Bucket 14	1373049

Where . represents the bucket to be having no amount belonging to the same.

Thanx in advance.

Re: Return Data Classes Even If No Records?

data_null__ — Sat, 14 Sep 2013 13:22:24 GMT

PRELOADFMT is the option you need when you have a value format as in your example. It can be used in SUMMARY/MEANS, REPORT and TABULATE

data bucker;
   x = 0; 
   run; 
PROC FORMAT; 
   value Buckets
       low -< 1 = 'Bucket 1'
        1 -< 30 = 'Bucket 2'
       30 -< 60 = 'Bucket 3'
       60 -< 90 = 'Bucket 4'
       90 -< 120 = 'Bucket 5'
      120 -< 150 = 'Bucket 6'
      150 -< 180 = 'Bucket 7'
      180 -< 210 = 'Bucket 8'
      210 -< 240 = 'Bucket 9'
      240 -< 270 = 'Bucket 10'
      270 -< 300 = 'Bucket 11'
      300 -< 330 = 'Bucket 12'
      330 -< 360 = 'Bucket 13'
      360 - High = 'Bucket 14'
      ;
   run; 
proc summary data=bucker nway completetypes; 
   class x / preloadfmt; 
   format x buckets.; 
   output out=counts;
   run; 
proc print; 
   run;

Message was edited by: data _null_ for no particular reason.

topic Return Data Classes Even If No Records? in SAS Programming

Return Data Classes Even If No Records?

Re: Return Data Classes Even If No Records?