topic Re: %put to print macro variable in SAS Programming

%put to print macro variable

mimi — Tue, 31 Jul 2012 05:34:21 GMT

Hi all,

The following macro works good but when I tried to print the macro variables using %put statement gives not found error.

But when I am not using proc sql in the cnts macro and into :tab or :tba , the put statement working fine. why is that error pls somebody help

me with it. Thanks in advance

%macro cnts(dis=, ind=, ovr=, tt=);

proc sql;

select count(distinct &dis.) format=2. into :&ovr.

from &ind.

where trt IN(&tt.);

quit;

%mend cnts;

%cnts(dis=patient, ind=ae, ovr=tab, tt='AB');

%cnts(dis=patient, ind=ae, ovr=tba, tt='BA');

%put " &tab. &tba.";

getting the following error msg

WARNING: Apparent symbolic reference TAB not resolved.

WARNING: Apparent symbolic reference TBA not resolved.

Re: %put to print macro variable

shivas — Tue, 31 Jul 2012 06:34:25 GMT

Hi,

Try this...not tested...

%macro cnts(dis=, ind=, ovr=, tt=);

%global tab;

proc sql;

select count(distinct &dis.) format=2. into :&ovr.

from &ind.

where trt IN(&tt.);

quit;

%mend cnts;

%put &tab;

Thanks,

Shiva

Re: %put to print macro variable

Patrick — Tue, 31 Jul 2012 08:29:42 GMT

Consider using code like below:

%macro cnts(dis=, ind=, ovr=, tt=);
proc sql;
    select count(distinct &dis.) format=2. into :&ovr.
    from &ind.
    where trt IN(&tt.);
quit;

%put %bquote(&ovr) has value %bquote(&&&ovr);

%mend cnts;

%cnts(dis=patient, ind=ae, ovr=tab, tt='AB');
%cnts(dis=patient, ind=ae, ovr=tba, tt='BA');

Re: %put to print macro variable

kuridisanjeev — Tue, 31 Jul 2012 11:51:25 GMT

Hi...

nothing wrong with your code..

you are trying to print the local macro variable values in outside of the macro.it can not be possible.

Use the put statement with in the Macro,then you can get the result.

Thanks

Sanjeev.K

Re: %put to print macro variable

yaswanthj — Tue, 31 Jul 2012 12:02:23 GMT

As per above

Please use below code..

%macro cnts(dis=, ind=, ovr=, tt=);

proc sql;

select count(distinct &dis.) format=2. into :&ovr.

from &ind.

where trt IN(&tt.);

quit;

%put " &&&ovr.";

%mend cnts;

%cnts(dis=patient, ind=ae, ovr=tab, tt='AB');

%cnts(dis=patient, ind=ae, ovr=tba, tt='BA');

Re: %put to print macro variable

Amir — Tue, 31 Jul 2012 12:27:02 GMT

Hi,

You can try making the argument passed to the macro function a global macro variable:

%macro cnts(dis=, ind=, ovr=, tt=);

%global &ovr; /* make available outside of macro function */

proc sql;

select count(distinct &dis.) format=2. into :&ovr.

from &ind.

where trt IN(&tt.);

quit;

%mend cnts;

%cnts(dis=patient, ind=ae, ovr=tab, tt='AB');

%cnts(dis=patient, ind=ae, ovr=tba, tt='BA');

%put " &tab. &tba.";

The %put statement does not require quotes to print the values.

Regards,

Amir.

Re: %put to print macro variable

Astounding — Tue, 31 Jul 2012 16:09:32 GMT

Well, if you really ran the program that you posted, you are trying to %PUT macro variables that don't exist.

There is no macro variable named &TAB.

There is no macro variable named &TBA

Some of the comments about global vs. local would apply if you try to examine &OVR.

Good luck.

Re: %put to print macro variable

Patrick — Tue, 31 Jul 2012 22:03:37 GMT

@Astounding

I believe you've missed the "select into :&ovr" bit in the macro. Macrovars &TAB and &TBA get created when the macro executes (values passed to OVR when calling the macro). It's about scope of the macro vars like others already said.

Re: %put to print macro variable

art297 — Tue, 31 Jul 2012 22:57:25 GMT

Of course you 'could' simply move to put statement into the macro. Does the following do what you are trying to accomplish?:

%macro cnts(dis=, ind=, ovr=, tt=);

proc sql noprint;

select count(distinct &dis.) format=2. into :&ovr.

from &ind.

where sex IN(&tt.);

quit;

%put &&&ovr.;

%mend cnts;

%cnts(dis=age, ind=sashelp.class, ovr=tab, tt='M')

%cnts(dis=age, ind=sashelp.class, ovr=tba, tt='F')

Re: %put to print macro variable

mimi — Wed, 01 Aug 2012 03:47:55 GMT

Thank you all for the answer. with in cnt macro Iwas able to print. I needed those variable to be stored as global . I needed those vars in the last step.

I just needed to check if the vars are storing the correct value. %global &ovr. worked fine for me .