topic Re: Find min for a list of variables in SAS Programming

Find min for a list of variables

hhchenfx — Wed, 16 Feb 2022 04:29:29 GMT

Hi,

I want to find record that: v1< min (v2,v3,v4.... vn).

Is there way rather than listing all v?

Thanks

HHC

data a; 
input id v1 v2 v3 v4 v5;
datalines;
1 4 5 6 7 8
2 5 9 10 85 3
3 99 1 2 3 4
;run;

data b; set a;
if v1< min(v2-v5); *SAS take it as minus;
run;

Re: Find min for a list of variables

mkeintz — Wed, 16 Feb 2022 04:57:14 GMT

Define an array containing V2-V5 (using v2-v5 expession), then find the minimum of that array, using the of arrayname{*} expression:

data a; 
input id v1 v2 v3 v4 v5;
datalines;
1 4 5 6 7 8
2 5 9 10 85 3
3 99 1 2 3 4
;run;

data b; set a;
  array _v2_thru_5 {*} v2-v5;
  if v1< min(of _v2_thru_5{*}); 
run;

Re: Find min for a list of variables

FreelanceReinh — Wed, 16 Feb 2022 08:57:37 GMT

Hi @hhchenfx,

For a numbered range list or a name range list (see documentation of SAS Variable Lists) you can use the OF operator without an array. Both of these are applicable to your example:

Numbered range list:

if v1 < min(of v2-v5);

Name range list:

if v1 < min(of v2--v5);

The OF operator signals that the hyphens between "v2" and "v5" are not minus signs.

Re: Find min for a list of variables

Kurt_Bremser — Wed, 16 Feb 2022 09:40:03 GMT

If the methods already proposed can work depends on the real names of your variables.

If you have such nicely numbered names, then the "of v2-v5" will work. But if you have names like a b c d e f (no numeric suffix, or no complete sequence), you will need the "of b--f" construct, but this depends on the physical sequence of variables within an observation, and that can change in numerous ways without you even noticing it (no WARNING, ERROR or NOTE in the log).

For the latter, I would go with a preceding step that extracts the necessary names from DICTIONARY.COLUMNS into a macro variable for use in the MIN function.