topic Re: Create Specific Sized Groups Using RAND("Table")? in SAS Programming

Create Specific Sized Groups Using RAND("Table")?

keherder — Wed, 09 Feb 2022 05:06:22 GMT

Hello! I am trying to assign participants to 3 groups using a discrete uniform "table" distribution. I am wondering if there is a way to add to this code to that I get exactly 200, 200, and 100 participants in each group:

data bios675.uniform (keep=treat);
call streaminit(2822);*Set seed;
p1=200/500; p2=200/500; p3=100/500;*Set probabilities of three treatment groups;
do i=1 to 500; *500 participants;
treat=rand("Table", p1, p2, p3);
output;
end;
run;

I'm wondering if there is somethign I can do like if a group reaches this number, than stop? Or something like that... Thank you!

Re: Create Specific Sized Groups Using RAND("Table")?

Ksharp — Wed, 09 Feb 2022 07:23:14 GMT

proc plan seed=17431;
factors group=10 subjid=500 / noprint;
output out=temp;
run;
data want;
 set temp;
 if subjid in (1:100) then treat=1;
 if subjid in (101:300) then treat=2;
 if subjid in (301:500) then treat=3;
run;

proc freq data=want;
table group*treat/list;
run;

Re: Create Specific Sized Groups Using RAND("Table")?

mkeintz — Wed, 09 Feb 2022 14:20:06 GMT

Keep track of the declining number of needed cases (N1, N2, N3) in each TREAT level, and the declining number of total available subjects:

data want (keep=treat);
  call streaminit(2822);*Set seed;
  array n {3} (200,200,100);
  do available=sum(of n{*}) to 1 by -1;
    treat=rand("Table",n1/available,n2/available,n3/available);
    output;
    n{treat}=n{treat}-1;
  end;
run;

Note: It can be shown that even though probabilities change over the course of the assignment process, every observation has an equal probability of being assigned to a given group.

Editted note: initially forgot to put in the streaminit. It's there now.

Re: Create Specific Sized Groups Using RAND("Table")?

keherder — Wed, 09 Feb 2022 14:24:43 GMT

Awesome, this is exactly what I needed, and makes sense! Thank you!