topic Re: Wide to Long of 1 row with adding vars labels info in SAS Programming

Wide to Long of 1 row with adding vars labels info

Ronein — Wed, 09 Feb 2022 10:22:04 GMT

Hello

What is the way to create wanted data set from have data set?

This is transpose of one row (wide) into long with putting var labels into one column in the desired data set

Data have;
label X1='abc' X2='frg' X3='Per' X4='Tim'  X5='Loc';
input X1 X2 X3 X4 X5;
cards;
100 200 50 300 180
;
Run;


Data wanted;
input field_name $ field_label $ value;
cards;
X1 abc 100
X2 frg 200
X3 per 50
X4 Tim 300
X5 Loc 180
;
Run;

Re: Wide to Long of 1 row with adding vars labels info

PeterClemmensen — Wed, 09 Feb 2022 10:27:47 GMT

Try this

data want;
   set have;
   array x x:;
   do over x;
      field_name = vname(x);
	  field_label = vlabel(x);
	  value = x;
	  output;
   end;
   keep field_name field_label value;
run;

Result:

field_name field_label value 
X1         abc         100 
X2         frg         200 
X3         Per         50 
X4         Tim         300 
X5         Loc         180

Re: Wide to Long of 1 row with adding vars labels info

andreas_lds — Wed, 09 Feb 2022 10:33:09 GMT

Proc transpose can do this:

proc transpose data=have out=want(rename=(col1 = value)) label=field_label name=field_name;
   var x1-x5;
run;