topic Re: Substring based on specific criteria in SAS Programming

Substring based on specific criteria

SAS_Muggle — Tue, 08 Feb 2022 20:05:14 GMT

I have the following date rows:

VAR1

This is row 1 (row1)

This is row 2 (I think) (row2)

(row3.)

And I need it to look like this:

row1

row2

row3

Basically I need to trim the string into the text in between the last parenthesis. Can anyone help with code to perform this?

Re: Substring based on specific criteria

PeterClemmensen — Tue, 08 Feb 2022 20:18:58 GMT

How about

data have;
input VAR1 $ 1-50;
datalines;
This is row 1 (row1)           
This is row 2 (I think) (row2) 
(row3.)                        
;

data want;
   if _N_=1 then r = prxparse('/\(([^)]*)\)[^(]*$/');
   set have;
   if prxmatch(r, VAR1) then var2 = prxposn(r, 1, VAR1);
   
   retain r;
   drop r;
run;

Result:

VAR1                            var2
This is row 1 (row1)            row1
This is row 2 (I think) (row2)  row2
(row3.)                         row3.

Re: Substring based on specific criteria

Ksharp — Wed, 09 Feb 2022 07:42:03 GMT

data have;
input VAR1 $ 1-50;
datalines;
This is row 1 (row1)           
This is row 2 (I think) (row2) 
(row3.)                        
;

data want;
 set have;  
 if substr(var1,length(var1))=')' then want=scan(var1,-1,'() ');
run;

Re: Substring based on specific criteria

Kurt_Bremser — Wed, 09 Feb 2022 08:13:16 GMT

Done with SCAN and COMPRESS:

data have;
input var1 $80.;
datalines;
This is row 1 (row1)
This is row 2 (I think) (row2)
(row3.)
;

data want;
set have;
var2 = compress(scan(var1,-1,"("),").");
run;