topic Re: Copy value for certain rows grouped by person in SAS Programming

Copy value for certain rows grouped by person

A_Halps — Mon, 07 Feb 2022 19:20:15 GMT

Hi,

I am trying to go from:

SSN TEST

1 1

2 4

2 2

3 2

TO:

SSN TEST FLAG

1 1 .

2 4 1

2 2 1

3 2 .

So, I want to create a flag that if the test=4 then each flag for that specific person will be 1.

This is what I currently have, but it is not grouping it by person and is continuing down the entire list, which is not what i want.

data want;
set have;
by ssn;
if test=4 then flag=1;
retain flag;
run;

Re: Copy value for certain rows grouped by person

PeterClemmensen — Mon, 07 Feb 2022 19:32:40 GMT

So if TEST = 4 for any obs in a group, then flag = 1 for all obs in that group?

Re: Copy value for certain rows grouped by person

PeterClemmensen — Mon, 07 Feb 2022 19:36:33 GMT

If so then do

data have;
input SSN TEST;
datalines;
1 1 
2 4 
2 2 
3 2 
;

data want;
   do _N_ = 1 by 1 until (last.ssn);
      set have;
	  by ssn;
	  if test = 4 then flag = 1;
   end;

   do _N_ = 1 to _N_;
      set have;
      output;
   end;
run;

Re: Copy value for certain rows grouped by person

A_Halps — Mon, 07 Feb 2022 19:36:43 GMT

Yes. And I currently have it set up with 4 is the top because i sorted it by ssn and descending test (4 is the highest it goes).

Re: Copy value for certain rows grouped by person

A_Halps — Mon, 07 Feb 2022 19:38:22 GMT

What does "_N_ = 1 " do?

Re: Copy value for certain rows grouped by person

PeterClemmensen — Mon, 07 Feb 2022 19:40:02 GMT

If you know that test = 4 is the first in each group, a simpler single-pass solution could be

data have;
input SSN TEST;
datalines;
1 1 
2 4 
2 2 
3 2 
;

data want;
   set have;
   by ssn;
   if first.ssn then flag = .;
   if test = 4 then flag = 1;
   retain flag;
run;