topic Re: Create a new date variable from a timestamp "2021-10-08 12:02:42" in SAS Programming

Create a new date variable from a timestamp "2021-10-08 12:02:42"

_maldini_ — Thu, 03 Feb 2022 20:12:48 GMT

I'm trying to create a new variable (i.e., a date, numeric) from an existing variable (i.e., a timestamp, character). I can use the SUBSTR function to pull out the date from the timestamp, but I can't figure out the next step.

DATA new;
	SET old;
	date=SUBSTR(informed_consent_hip_v_0, 1, 10);
RUN;

The timestamp values follow this format: "2021-10-08 12:02:42"

After using the SUBSTR function, the value of "date" is "2021-10-08".

How can I convert "2021-10-08" to a SAS date? Will it automatically convert it to a numeric variable?

Thanks.

Re: Create a new date variable from a timestamp "2021-10-08 12:02:42"

PeterClemmensen — Thu, 03 Feb 2022 20:16:55 GMT

Use the Input Function like this

DATA _null_;
	dt = "2021-10-08 12:02:42";
	date = input(substr(dt, 1, 10), yymmdd10.);
	put date = date9.;
RUN;

Re: Create a new date variable from a timestamp "2021-10-08 12:02:42"

ballardw — Thu, 03 Feb 2022 20:29:02 GMT

Actually don't even need the substring. The Informat will use the number of characters you specify:

      

DATA _null_;
	dt = "2021-10-08 12:02:42";
	date = input(dt, yymmdd10.);
	put date = date9.;
RUN;

Re: Create a new date variable from a timestamp "2021-10-08 12:02:42"

Reeza — Thu, 03 Feb 2022 20:42:43 GMT

DATA want;
	dt = "2021-10-08 12:02:42";
	datetime = input(dt, anydtdtm.);
	date = datepart(datetime);
	put date = date9. datetime = datetime22.;
RUN;

One other option - read in as datetime and parse out the date.

Re: Create a new date variable from a timestamp "2021-10-08 12:02:42"

PeterClemmensen — Fri, 04 Feb 2022 07:20:29 GMT

@ballardw Good catch 🙂