topic Re: Reading a CSV having a custom delimiter in SAS Programming

Reading a CSV having a custom delimiter

Florent — Tue, 22 May 2012 15:23:44 GMT

Hi all,

Would you know how I could read a CSV in which the delimiter as been set to a double pipe ('||') ? An empty value in this file would thus appear like 4 consecutive pipe ('||||'). We are still using the version 8 of SAS :smileylaugh:

I already know how to create such a file but not how to read it :smileyconfused:

Many thanks in advance for your help !

Kind regards,

Florent

Re: Reading a CSV having a custom delimiter

MikeZdeb — Tue, 22 May 2012 15:35:25 GMT

hi ... I think that _INFILE_ has been around since V8, so maybe ...

data x;

infile datalines dsd;

input @;

_infile_ = tranwrd(_infile_,'||',',');

input a b c;

datalines;

1||2||||

4||5||6

||8||||

;

a b c

1 2 .

4 5 6

. 8 .

ps ... some reading material ...

More _Infile_ Magic, Peter Crawford

http://www2.sas.com/proceedings/sugi28/086-28.pdf

Now _INFILE_ is an Automatic Variable − So What?, Howard Schreier,

http://www.nesug.org/proceedings/nesug01/cc/cc4018bw.pdf

Re: Reading a CSV having a custom delimiter

Florent — Tue, 22 May 2012 15:43:03 GMT

Thanks, it makes the job !

Re: Reading a CSV having a custom delimiter

Astounding — Tue, 22 May 2012 16:24:22 GMT

Nice solution, but I'm not sure you should use dsd here. The way I understood the data structure, a double delimiter indicates there is a blank variable. If that's the case, dsd should become dlm=','

Re: Reading a CSV having a custom delimiter

MikeZdeb — Tue, 22 May 2012 16:34:14 GMT

hi ... DSD implies a few things: a comma-delimiter; two consecutive commas indicate a missing value; considers delimiters within quotes as character data and strips quotes from quoted values

DLM=',' only does the comma-delimter portion

my example doesn't work with just DLM

Re: Reading a CSV having a custom delimiter

Astounding — Tue, 22 May 2012 16:36:51 GMT

You're right, I'm temporarily brain-fried. Sorry about that.

Re: Reading a CSV having a custom delimiter

PGStats — Tue, 22 May 2012 16:42:23 GMT

Hi, My concern would be that a file separated this way might contain commas in numeric or character fields. It might be safer to keep the pipe character as in:

data x;

infile datalines delimiter='|' dsd;

input @;

_infile_ = tranwrd(_infile_,'||','|');

input (a b c) (:$);

datalines;

1||2,5||||

4||5||6

||8||||

;

Re: Reading a CSV having a custom delimiter

data_null__ — Tue, 22 May 2012 17:47:44 GMT

I agree that changing the delimiter to comma might cause problem. I would choose a character that is even more obscure. Something untypeable perhaps.

Re: Reading a CSV having a custom delimiter

PGStats — Tue, 22 May 2012 17:53:39 GMT

The NUL character, of course! :smileylaugh: