topic Re: proc pint option grand_total in SAS Programming

proc pint option grand_total

BrahmanandaRao — Tue, 11 Jan 2022 07:41:54 GMT

data sales;
input salesperson $ January February March ;
datalines;
Smith           1000        650        800
Johnson            0        900        900
Reed            1200        700        850
Davis           1050        900       1000
Thompson         750        850       1000
Peterson         900        600        500
Jones            800        900       1200
Murphy           700        800        700
Garcia           400       1200       1150
;
run;

proc print data=sales noobs sumlabel='Total' grandtotal_label='Grand Total' ;
sum January February March  ;
run;

I want to grand_total using grand_totallabel option but its not give

Re: proc pint option grand_total

Kurt_Bremser — Tue, 11 Jan 2022 08:06:58 GMT

The label is displayed in the obs number column, so you need to omit the NOOBS option:

proc print
  data=sales
  sumlabel='Total'
  grandtotal_label='Grand Total'
;
sum January February March;
run;

If you want it in the salesperson column, use PROC REPORT:

proc report data=sales;
column salesperson january february march;
define salesperson / display;
define january / sum;
define february / sum;
define march / sum;
rbreak after / summarize;
compute after;
  salesperson = "Grand Total";
endcomp;
run;

Re: proc pint option grand_total

BrahmanandaRao — Tue, 11 Jan 2022 08:44:46 GMT

proc sort data=sashelp.class out=class;                                    
   by sex;                                                                 
run;  
                                                             
proc format;                                                               
   value $genderf                                                          
      'F'='Female'                                                         
      'M'='Male';                                                          
run;                                              
                                                                           
proc print data=class noobs                                                
     sumlabel='#byval(sex) Total' grandtotal_label='Grand Total';   
   by sex;                                                                 
   var name age height weight;                                             
   sum height weight;                                                                                                                                 
   format sex $genderf.;                                                   
run;

Re: proc pint option grand_total

Kurt_Bremser — Tue, 11 Jan 2022 09:20:23 GMT

When you use BY, PROC PRINT knows where to put that label. Without BY, it can only use the obs column.

Re: proc pint option grand_total

ballardw — Tue, 11 Jan 2022 16:07:23 GMT

I generally use a different report procedure, either Tabulate or Report to have more control over things and avoid the sometimes esoteric interactions of the Proc Print options.

proc tabulate data=sales;
   class salesperson;
   var January February March;
   table salesperson='' All='Grand Total'  ,
         (January February March)*sum=''*f=best8.
         /box = 'Sales Person'
   ;
run;

Also it seems like as soon as I do the basic report I get asked something like "What is the mean for each Sales person?" which Proc Print won't do.