topic Re: i have 100 variable i need sum of variable column wise in SAS Programming

i have 100 variable i need sum of variable column wise

aanan1417 — Tue, 11 Jan 2022 04:40:38 GMT

i can do this using proc sql but my variables are 100 so it will take lot of time .Is their any other way so that i haven't to wright 100 variable in select statement

data a;

input s1 s2 s3 s4;

datalines;

1 2 3 4

2 2 4 5

9 9 9 9

;

run;

output

s1 s2 s3 s4

12 13 16 18

Re: i have 100 variable i need sum of variable column wise

mkeintz — Tue, 11 Jan 2022 05:57:21 GMT

This is where the various analysis and reporting PROCs in SAS excel. In your case, it would be PROC SUMMARY:

data a;
  input s1 s2 s3 s4;
datalines;
1  2  3 4
2  2  4  5
9  9  9  9
run;
proc summary data=a  ;
  var s1-s4;
  output out=want (drop=_type_ _freq_)  sum=;
run;

Re: i have 100 variable i need sum of variable column wise

SASKiwi — Tue, 11 Jan 2022 05:59:57 GMT

Assuming your variables are named s1 to s100 something like this should work:

proc summary data = a sum;
  var s1 - s100;
  output out = a_sum
         sum = ;
run;

Re: i have 100 variable i need sum of variable column wise

andreas_lds — Tue, 11 Jan 2022 06:49:06 GMT

What do you need exactly as result? A dataset with the sums? Html-Output? The sums appended to the dataset you have?

Using proc summary is highly recommended, but if you can use IML, this maybe a good point to start, because it is designed to work with matrices.

proc iml;
   use work.a;
   read all var _num_ into have;
   close work.a;
   
   want = have[+,];
   print want;
quit;

Re: i have 100 variable i need sum of variable column wise

LinusH — Tue, 11 Jan 2022 07:07:34 GMT

Transpose!

There are just a few scnarios when a wide table make s sense.

A long table structure is easier to query, optimizes storage etc.

Re: i have 100 variable i need sum of variable column wise

Ksharp — Tue, 11 Jan 2022 11:42:11 GMT

data a;
input s1 s2 s3 s4;
datalines;
1 2 3 4
2 2 4 5
9 9 9 9
;

proc summary data=a;
var _numeric_;
output out=want(drop=_type_ _freq_) sum=;
run;