topic Re: Changing data values with date formats not working properly and giving me the wrong dates in SAS Programming

Changing data values with date formats not working properly and giving me the wrong dates

carmong — Fri, 07 Jan 2022 20:33:22 GMT

I am attempting to change the appearance of Data values with date formats, but the dates are not converting property and giving me the wrong dates.

I am trying to change DATETIME19. to a different format but the dates are coming out wrong (I would like to have it in the mmddyy format but tried other formats)

I have used the following code:

data deltbl; set deletion;
date2 = input(AdmitDate,anydtdte10.);
format date2 date9.;
datec = put(date2,date9.);
run;

I have also tried the following to change mmddyy.10 and it still isn't coming out right

data deltbl; set deletion;
date2 = input(AdmitDate,anydtdte10.);
format date2 mmddyy10.;
addate = put(date2,mmddyy10.);
hosp =catx("_", ref_HospitalCode, MRN, addate);
run;

Re: Changing data values with date formats not working properly and giving me the wrong dates

Reeza — Sat, 08 Jan 2022 18:38:46 GMT

Your code is mostly correct except you have a date time, not a date. Use the Datepart() function on the variable to get only the date portion.
Use ANYDTDTM to read in a date time instead of date.

Here's a great, but longer and in depth, reference for dates and times in SAS
https://communities.sas.com/t5/SAS-Communities-Library/Working-with-Dates-and-Times-in-SAS-Tutorial/ta-p/424354

@carmong wrote:

I am attempting to change the appearance of Data values with date formats, but the dates are not converting property and giving me the wrong dates.

I am trying to change DATETIME19. to a different format but the dates are coming out wrong (I would like to have it in the mmddyy format but tried other formats)

I have used the following code:

data deltbl; set deletion;
date2 =datepart( input(AdmitDate,anydtdtm.));
format date2 date9.;
datec = put(date2,date9.);
run;

Re: Changing data values with date formats not working properly and giving me the wrong dates

carmong — Fri, 07 Jan 2022 23:35:04 GMT

Thank you for your response. Where would I put that in my code (and can you post an example)?

Re: Changing data values with date formats not working properly and giving me the wrong dates

Tom — Fri, 07 Jan 2022 23:54:24 GMT

The INPUT function is for converting character strings into values. But your variable appears to be a DATETIME numeric variable, not a character string. If you try to use a number as the first parameter to the INPUT() function SAS will have to first convert it to a character string. It will use the BEST12. format to do that.

SAS stores DATETIME values as number of seconds. Midnight on the 8th of May in 2020 is the number 1,904,515,200 which when printed using the BEST12. format will be the string " 1904515200". Since your informat is only using the first 10 characters that will look like the string 19045152. Which only makes sense as a date if you treat is as DDMMYYYY style. Hence you have created the date of APR 19, 5152.

You just want to use the DATEPART() function to convert the number of seconds in your datetime variable to a number of days. Then you can use the DATE format to display it.

data deltbl;
  set deletion;
  date2 = datepart(AdmitDate);
  format date2 date9.;
  datec = put(date2,date9.);
run;

Or you could leave your variable as DATETIME and use the DTDATE format to display just the date part.

Re: Changing data values with date formats not working properly and giving me the wrong dates

Reeza — Sat, 08 Jan 2022 18:31:05 GMT

I modified your code in the answer.