topic Re: char function add left zeroes in SAS Programming

char function add left zeroes

Zaghini — Thu, 09 Dec 2021 09:06:28 GMT

I have a char variable VAR1 with these values

'56'
'152'
'7'

and I need to create a new variable VAR2 that adds some left zeroes till 8 characters like

'00000056'
'00000152'
'00000007'

which function I have to use?

thank you all.

Re: char function add left zeroes

japelin — Thu, 09 Dec 2021 09:36:16 GMT

If Var1 value is only number, you can use z format.

data have;
  length VAR1 $8;
  VAR1='56';output;
  VAR1='152';output;
  VAR1='7';output;
run;

data want;
  length VAR2 $8;
  set have;
  VAR2=put(input(VAR1,best.),z8.);
run;

use repeat function

data want;
  length VAR2 $8;
  set have;
  VAR2=cats(repeat('0',8-length(VAR1)-1),VAR1);
run;

Re: char function add left zeroes

Ksharp — Thu, 09 Dec 2021 12:34:49 GMT

data have;
  length VAR1 $8;
  VAR1='56';output;
  VAR1='152';output;
  VAR1='7';output;
run;

data want;
 set have;
 length want $ 8;
 want=left(var1);
 want=translate(right(want),'0',' ');
run;

Re: char function add left zeroes

Zaghini — Fri, 10 Dec 2021 07:17:40 GMT

thanks @Ksharp @japelin ,

it works!