topic How to identify customer who made only one payment method? in SAS Programming

How to identify customer who made only one payment method?

David_Billa — Mon, 06 Dec 2021 09:19:19 GMT

I've the data as follows. I want to identify the customer details who made only CASH as payment method. Here if I use where clause as 'Cash' in payment_method then I get Rohan also in my result and it is not correct.

ID	CUST_NAME	PAYMENT_METHOD	PAYNT_DT
6	Geetha	Cash	03-02-2021
8	Geetha	Cash	04-02-2021
2	Ram	Online	03-01-2021
1	Rohan	Cash	01-01-2021
3	Rohan	Cash	02-02-2021
5	Vijay	Online	03-02-2021
7	Vijay	Cash	03-02-2021

Desired Result:

ID	CUST_NAME	PAYMENT_METHOD	PAYNT_DT
6	Geetha	Cash	03-02-2021
8	Geetha	Cash	04-02-2021
1	Rohan	Cash	01-01-2021
3	Rohan	Cash	02-02-2021

Any help?

Re: How to identify customer who made only one payment method?

Kurt_Bremser — Mon, 06 Dec 2021 10:00:03 GMT

data want,
merge
  have
  have (
    in=no
    keep=name payment_method
    rename=(payment_method=_pay)
    where=(_pay ne 'Cash')
  )
;
if not no;
drop _pay;
run,

Untested, no usable data supplied.

Re: How to identify customer who made only one payment method?

ChrisNZ — Mon, 06 Dec 2021 10:51:39 GMT

@Kurt_Bremser forgot the BY statement., and to account for possible duplicates.

proc sort data=HAVE out=NOCASH(keep=ID) nodupkey
  by ID;
  where PAYMENT_METHOD ne 'Cash';
run;
data WANT,
  merge HAVE NOCASH;
  by ID;
  if not NOCASH;
run,

Re: How to identify customer who made only one payment method?

Ksharp — Mon, 06 Dec 2021 11:55:05 GMT

data have;
infile cards expandtabs truncover;
input ID CUST_NAME $ PAYMENT_METHOD $ PAYNT_DT : $20.;
cards;
6 Geetha Cash 03-02-2021
8 Geetha Cash 04-02-2021
2 Ram Online 03-01-2021
1 Rohan Cash 01-01-2021
3 Rohan Cash 02-02-2021
5 Vijay Online 03-02-2021
7 Vijay Cash 03-02-2021
;

proc sql;
create table want as
select * from have
 group by CUST_NAME
  having count(*)=sum(PAYMENT_METHOD='Cash');
quit;

Re: How to identify customer who made only one payment method?

Kurt_Bremser — Mon, 06 Dec 2021 12:05:08 GMT

Yep, I forgot the BY. But you do not need to dedup, because a) the lookup is always a subset of the whole, and b) as soon as any observation is found there, the whole customer is discarded anyway, so it can't cause additional observations. It will cause a NOTE about multiple occurences (leaving a comment about that in the code will be nice), but that's it.

Re: How to identify customer who made only one payment method?

David_Billa — Mon, 06 Dec 2021 13:23:42 GMT

@Ksharp Thanks, your code is producing the desired results. Could you please explain this step? How you're summing the character field - 'PAYMENT_METHOD'?

having count(*)=sum(PAYMENT_METHOD='Cash')

Re: How to identify customer who made only one payment method?

Kurt_Bremser — Mon, 06 Dec 2021 13:59:32 GMT

It does not sum the variable (which would not be possible with a character value), but the result of the comparison, which is Boolean. Boolean in SAS is numeric, with values 0 (false) or 1 (true).

Re: How to identify customer who made only one payment method?

David_Billa — Tue, 07 Dec 2021 05:58:38 GMT

@ChrisNZ I'm getting an error message saying that 'By variables are not properly sorted on dataset WORK.HAVE' although it was sorted in your code.

Re: How to identify customer who made only one payment method?

ChrisNZ — Tue, 07 Dec 2021 06:04:40 GMT

One of the tables is sorted in my code. You need both sorted (or indexed).

But you only need one (sorted) table: Kurt's code should work once the input table is sorted (or indexed), and after you add the BY statement.

Re: How to identify customer who made only one payment method?

David_Billa — Tue, 07 Dec 2021 06:10:00 GMT

@Kurt_Bremser May I know how this comparison will be true?

having count(*)=sum(PAYMENT_METHOD='Cash')

Re: How to identify customer who made only one payment method?

Kurt_Bremser — Tue, 07 Dec 2021 07:06:57 GMT

In every observation where payment_method equals 'Cash', a 1 is counted, otherwise a zero. SUM is a SQL Summary Function that works over all observations (in a group, if GROUP BY is used).

Re: How to identify customer who made only one payment method?

ChrisNZ — Tue, 07 Dec 2021 07:08:44 GMT

having count(*)=sum(PAYMENT_METHOD='Cash')

This means: keep groups where number of records = number of records with PAYMENT_METHOD='Cash'