topic Re: loop scan dates values coming from variable of table in SAS Programming

loop scan dates values coming from variable of table

Nasser_DRMCP — Fri, 03 Dec 2021 11:42:04 GMT

Hello, data have; input jour DDMMYY10. ; format jour DDMMYY10. ; datalines; 01/01/2022 02/01/2022 03/01/2022 04/01/2022 05/01/2022 06/01/2022 07/01/2022 08/01/2022 09/01/2022 10/01/2022 11/01/2022 ; proc sql; select distinct jour into :liste_jour separated by ' ' from have ; quit ; %put &liste_jour; by executing this code above the result is 01/01/2022 02/01/2022 03/01/2022 04/01/2022 05/01/2022 06/01/2022 07/01/2022 08/01/2022 09/01/2022 10/01/2022 11/01/2022 But my problem is when I try to get each date value for loop like this below; the result is not corret because it is 01 and 01 and 2021... thanks in advance for your help kind regards Nass %macro mc_boucle_surlesjours ; %local i next_jour; %let i=1; %do %while (%scan(&liste_jour, &i) ne ""); %let next_jour = %scan(&liste_jour, &i); %put -->&next_jour ; %let i = %eval(&i + 1); %end ; %mend ; %mc_boucle_surlesjours ;

Re: loop scan dates values coming from variable of table

PaigeMiller — Fri, 03 Dec 2021 11:53:41 GMT

Please re-format your problem description to make it readable. Thanks.

Re: loop scan dates values coming from variable of table

Nasser_DRMCP — Fri, 03 Dec 2021 12:28:13 GMT

I have a table with a variable "day" that containes dates values like "01/01/022" "02/01/2022" "03/01/2022" … I would that a macro variable gets each values by usinf a loop

Re: loop scan dates values coming from variable of table

PaigeMiller — Fri, 03 Dec 2021 12:41:03 GMT

Repeating:

Please re-format your problem description to make it readable.

Re: loop scan dates values coming from variable of table

Nasser_DRMCP — Fri, 03 Dec 2021 12:55:21 GMT

I would like to write a loop step with the objectif is to put into a variable the values 01/01/2022 for iteration 1 02/01/2022 for iteration 2 03/01/2022 for iteration 3 04/01/2022 ... 05/01/2022 06/01/2022 07/01/2022 08/01/2022 09/01/2022 10/01/2022 11/01/2022 for the last iteration

Re: loop scan dates values coming from variable of table

Nasser_DRMCP — Fri, 03 Dec 2021 12:57:59 GMT

by executing this %macro mc_boucle_surlesjours ; %local i next_jour; %let i=1; %do %while (%scan(&liste_jour, &i) ne ); %let next_jour = %scan(&liste_jour, &i); %put -->&next_jour ; %let i = %eval(&i + 1); %end ; %mend ; %mc_boucle_surlesjours ; the result is -->01 -->01 -->2022 -->02 -->01 -->2022 -->03 -->01 -->2022 -->04 -->01 -->2022 -->05 -->01 -->2022 -->06 -->01 -->2022 -->07 ...

Re: loop scan dates values coming from variable of table

Nasser_DRMCP — Fri, 03 Dec 2021 14:01:32 GMT

ok I found the solution.see below. in the scan I forgot to specify the separator space. this code below works as I intended

%macro mc_boucle_surlesjours ;
 %local i next_jour;
 %let i=1;
 %do %while (%scan(&liste_jour, &i, " ") ne );
   %let next_jour = %scan(&liste_jour, &i, " ");
   %put -->&next_jour ;
   %let i = %eval(&i + 1);
 %end ; 
%mend ;

Re: loop scan dates values coming from variable of table

ballardw — Fri, 03 Dec 2021 13:09:12 GMT

Read your post and then look at this:

data have;
 input jour DDMMYY10. ;
 format jour DDMMYY10. ;
 datalines;
01/01/2022
02/01/2022
03/01/2022
04/01/2022
05/01/2022
06/01/2022
07/01/2022
08/01/2022
09/01/2022
10/01/2022
11/01/2022
;
 proc sql noprint;
 select distinct jour into :liste_jour separated by ' ' from have ;
 quit ;
 %put &liste_jour;


%macro mc_boucle_surlesjours ;
 %local i next_jour;
 %do i = 1 %to %sysfunc(countw(&liste_jour,%str( )));
 
    %let next_jour = %scan(&liste_jour, &i,%str( ));
    %put -->&next_jour ;

 %end ;
 %mend ;
 %mc_boucle_surlesjours ;

That is part of what is meant by "reformat your post".

The above does part of what I think you want.

Problem: using SCAN by default will treat the / character as delimiter between words. The fix above forces a space into the parameters for Countw and Scan functions as the only delimiter.

Or depending on how you expect to use those dates do not apply a format. Really the only time a macro Date value should be formatted is when it is read my humans such as in a title, footnote or possibly a file name.

If you do not format the date variable you will get the numbers that represent the date and can be used if comparisons or other date related functions and would not need the forced space from the %Str

Re: loop scan dates values coming from variable of table

PaigeMiller — Fri, 03 Dec 2021 13:19:57 GMT

@Nasser_DRMCP wrote:
by executing this %macro mc_boucle_surlesjours ; %local i next_jour; %let i=1; %do %while (%scan(&liste_jour, &i) ne ); %let next_jour = %scan(&liste_jour, &i); %put -->&next_jour ; %let i = %eval(&i + 1); %end ; %mend ; %mc_boucle_surlesjours ; the result is -->01 -->01 -->2022 -->02 -->01 -->2022 -->03 -->01 -->2022 -->04 -->01 -->2022 -->05 -->01 -->2022 -->06 -->01 -->2022 -->07 ...

Do not post code as plain unformatted text. Post code in the box that appears when you click on the "Insert SAS Code" icon. You may have found the correct answer, but again, I ask you to re-format it to be readable by using the "Insert SAS Code" icon, for the benefit of everyone else.

Re: loop scan dates values coming from variable of table

Nasser_DRMCP — Fri, 03 Dec 2021 13:17:56 GMT

thank you very much very clear and very interesting