topic Re: File name change in SAS Programming

File name change

Emma2021 — Thu, 25 Nov 2021 06:56:38 GMT

I have 2 csv files in c:\ drive.
How can I change file names by swapping each one without uploading/importing into sas?
I have: test.csv and test1.csv

I want to change test.csv to test1.csv
And test1.csv to test.csv

Thank you.

Re: File name change

japelin — Thu, 25 Nov 2021 07:05:23 GMT

For example, you could try using a different file name once.

options noxwait xsync;
x 'rename C:\Temp\test.csv text0.csv';
x 'rename C:\Temp\test1.csv text.csv';
x 'rename C:\Temp\test0.csv text1.csv';

Re: File name change

andreas_lds — Thu, 25 Nov 2021 07:06:32 GMT

If this has to be done in a sas session, using the rename function in a data step seems to be the best choice.

Re: File name change

ChrisNZ — Thu, 25 Nov 2021 07:19:30 GMT

[Deleted]

@andreas_lds's reply is better.

Re: File name change

Kurt_Bremser — Thu, 25 Nov 2021 07:29:45 GMT

If your SAS runs on a remote server, you (most probably) cannot do this from SAS code. You would need to share your C: drive to the network and mount it on the SAS server.

Re: File name change

Emma2021 — Thu, 25 Nov 2021 14:49:36 GMT

My sas is on my local not server based

Re: File name change

Emma2021 — Thu, 25 Nov 2021 14:50:35 GMT

Thank you, but it does not do anything. Should I add a line of code perhaps “run;”?

Re: File name change

Reeza — Thu, 25 Nov 2021 15:58:41 GMT

I would not recommend X command statements - they will work on your computer but not necessarily any system.
Using the RENAME function will work in any OS making your code more portable. Note that if you're swapping names, you'll need a temporary name for one of them to avoid conflicts.
The usage is the same as with FCOPY/FINFO from your previous question.

Re: File name change

Kurt_Bremser — Thu, 25 Nov 2021 17:16:19 GMT

The problem with the X statement is that it does not really tell you what happened. Use PIPE to retrieve the responses of the command:

data commands;
input command $80.; /* safe because DATALINES are always padded to at least 80 characters */
datalines;
rename C:\Temp\test.csv text0.csv
rename C:\Temp\test1.csv text.csv
rename C:\Temp\test0.csv text1.csv
;

data _null_;
set commands;
command = catx(" ",command,'2>&1'); /* reroutes stderr to stdout, so everything is caught */
infile dummy pipe filevar=command eof=done;
start:
  input;
  put _infile_;
  go to start;
done:
run;

Untested, as On Demand runs with NOXCMD.

Re: File name change

Emma2021 — Sun, 28 Nov 2021 17:12:35 GMT

Thanks, but it does not do anything either.

Re: File name change

Tom — Sun, 28 Nov 2021 17:55:45 GMT

Try using the RENAME() function.

Example:

* Create two files ;
data _null_;
  file 'c:\downloads\file1.csv' ;
  put 'file1';
  file 'c:\downloads\file2.csv' ;
  put 'file2';
run;

* Use the RENAME() function to "swap" them ;
data _null_;
  if fileexist('c:\downloads\temp') then put 'Will not work because temp file already exists';
  else do;
    rc1=rename('c:\downloads\file1.csv','c:\downloads\temp','file');
    rc2=rename('c:\downloads\file2.csv','c:\downloads\file1.csv','file');
    rc3=rename('c:\downloads\temp','c:\downloads\file2.csv','file');
    put (rc1-rc3)(=);
  end;
run;

* check that it worked ;
data _null_;
  infile 'c:\downloads\file1.csv' ;
  input;
  put _infile_;
  infile 'c:\downloads\file2.csv' ;
  input;
  put _infile_;
run;

Re: File name change

Kurt_Bremser — Sun, 28 Nov 2021 17:55:54 GMT

Please post the whole log of the data step in a code box (</> button).

Re: File name change

starrtiktokk — Mon, 29 Nov 2021 10:43:12 GMT

I would not recommend X command statements - they will work on your computer but not necessarily any system.

Re: File name change

Kurt_Bremser — Mon, 29 Nov 2021 11:53:17 GMT

Maxim 14 says "Use the Right Tool".

When you can do a complex action with a one line system command instead of 100 lines of SAS code (and much quicker at that!), there is no question which is the better option.