topic Re: Numbering of Groups in SAS Programming

Numbering of Groups

adamhyman — Thu, 17 May 2012 18:37:52 GMT

If I have a sorted table like this:

DATA myfruit;

INPUT fruit $40.;

DATALINES;

APPLE
APPLE

APPLE
PEACH
PEACH

;

RUN;

I would like to add the "Count" column like this:

Fruit	Count
APPLE	1
APPLE	2
APPLE	3
PEACH	1
PEACH	2

I know that I have to do something like this, I can't get it quite right.

data myfruit;

set myfruit;

by fruit;

Count = _N_;

run;

Any help would be greatly appreciated.

Thanks!
Adam

Re: Numbering of Groups

adamhyman — Thu, 17 May 2012 19:12:57 GMT

I worked it out, so am posting the solution.

data myfruit;

set myfruit;

by fruit;

retain count;

if first.fruit then count = 1;

else count + 1;

run;

Re: Numbering of Groups

MikeZdeb — Thu, 17 May 2012 19:13:17 GMT

hi ...

data myfruit;

set myfruit;

by fruit;

count + (-first.fruit * count) + 1;

run;

ps ... http://www.sascommunity.org/wiki/Tips:Between_and_Within_Group_Counters

Re: Numbering of Groups

Ksharp — Fri, 18 May 2012 03:50:10 GMT

Assuming your dataset has already sorted before.

DATA myfruit;
   INPUT fruit $40.;
   DATALINES;
APPLE
APPLE
APPLE
PEACH
PEACH
;
RUN;

data myfruit;
set myfruit;
if fruit ne lag(fruit) then count=0;
Count+1;
run;

Ksharp

Re: Numbering of Groups

Haikuo — Tue, 22 May 2012 14:07:58 GMT

Can also use DOW's counter:

data want;

do count=1 by 1 until (last.fruit);

set myfruit; by fruit; output;

end;

run;

Haikuo