topic Re: SAS Date in YYYYMMDDHHMMSS format in SAS Programming

SAS Date in YYYYMMDDHHMMSS format

DeepakSwain — Tue, 12 Oct 2021 17:36:15 GMT

Hi there,

I need your kind help to get system date in YYYYMMDDHHMMSS format.

data _null_;
export_date=put(datetime(), datetime20.);
put export_date;
run;

Re: SAS Date in YYYYMMDDHHMMSS format

AMSAS — Tue, 12 Oct 2021 17:44:04 GMT

Is this close enough:

data _null_;
  export_date=put(datetime(), E8601DT.);
  put export_date;
run;

See Dictionary of Formats for a list of formats

Re: SAS Date in YYYYMMDDHHMMSS format

PeterClemmensen — Tue, 12 Oct 2021 17:44:47 GMT

How about

data _null_;
export_date=put(datetime(), B8601DT.);
put export_date;
run;

Re: SAS Date in YYYYMMDDHHMMSS format

DeepakSwain — Tue, 12 Oct 2021 17:45:00 GMT

Date will look like 20211012134021

Re: SAS Date in YYYYMMDDHHMMSS format

PaigeMiller — Tue, 12 Oct 2021 17:49:30 GMT

I don't think there is a format that is exactly YYYYMMDDHHMMSS, this comes close:

data null;
export_date=datetime();
format export_date b8601dt20.0;
run;

If that isn't close enough, the PICTURE statement in PROC FORMAT allows you to create your own custom date/time formats that will match exactly.

Re: SAS Date in YYYYMMDDHHMMSS format

DeepakSwain — Tue, 12 Oct 2021 17:50:13 GMT

e8601dt20. will return 2021-10-21T13:46:07.
I want 20211021134607.

Re: SAS Date in YYYYMMDDHHMMSS format

PeterClemmensen — Tue, 12 Oct 2021 17:50:58 GMT

If you want an exact match, you can roll out your own format like this

proc format; 
  picture dtfmt (default=30)
    other = '%Y%0m%0d%0H%0M%0S' (datatype=datetime)
  ;
run;

data _null_;
  export_date=put(datetime(), dtfmt.);
  put export_date;
run;

Re: SAS Date in YYYYMMDDHHMMSS format

ballardw — Tue, 12 Oct 2021 17:57:38 GMT

@DeepakSwain wrote:
Date will look like 20211012134021

Requires custom format:

proc format;
picture mydatetime
low-high='%Y%0m%0d%0H%0M%0S' (datatype=datetime)
;
run;

data example;
   x='12Oct2021:13:40:21'dt;
   put x= mydatetime.;
run;

The directives in the Picture statement are case sensitive, the m is month, M is minutes mix them up and don't expect to understand any result. Also this is one place that you really need to use single quotes around the directives for the format, otherwise the directives get interpreted as macro calls and will throw errors. It will be up to you to make sure that the format is available in any session than needs to use this.

Re: SAS Date in YYYYMMDDHHMMSS format

PeterClemmensen — Tue, 12 Oct 2021 18:00:55 GMT

@ballardw Great minds think alike 😉