topic Re: How to input grouped data into SAS in SAS Programming

How to input grouped data into SAS

westbestern — Wed, 06 Oct 2021 19:12:29 GMT

I want to input this information into SAS

So far I have

data RCT;

input treatment $ outcome $;

I'm not sure how to enter the information under datalines, and I'm not sure if I have the input statement in correctly. How do I go about doing this?

Re: How to input grouped data into SAS

Reeza — Wed, 06 Oct 2021 19:21:39 GMT

You have two column headers in your INPUT but three in the table....
Type the data below the INPUT statement separated by a single space with 4 semicolons to end the lines. Note that $ indicates a character variable, ie values like A, B, C. If you read in your numbers as characters you cannot do math on those fields.

data want;
input trt sick well;
cards;
1 5 6
2 5 30
;;;;;
run;

Re: How to input grouped data into SAS

data_null__ — Wed, 06 Oct 2021 19:32:34 GMT

How about this...

data example;
   do trt = 'Placebo','Drug';
      do outcome = 'Sick','Well';
         input count @;
         output;
         end;
      end;
   stop;
   datalines;
30 10
15 40
;;;;
   run;
proc print;
   run;

Re: How to input grouped data into SAS

ballardw — Wed, 06 Oct 2021 19:32:59 GMT

It may help to decide/ show what the output data set looks like or tell us how you expect to use the data.

This looks like a summary table where the numbers are likely counts of the outcome.

If this were my data, and that is all there is perhaps:

data want;
   input treatment $ outcome $ count;
datalines;
Placebo  Sick 30
Placebo  Well 10
Drug     Sick 15
Drug     Well 40
;

In many forms of analysis a variable that indicates the number of results, using either a WEIGHT or FREQ statement will use the count.

Example:

Proc freq data=want;
   tables treatment*outcome/ chisq expected;
   weight count;
run;

Which generates a table of the counts comparing treatment and outcome, with percentages, the expected count if there were no differences in the distribution of outcomes between the two treatments and a chi-squared test for similarity of distribution (not similar in this case).