topic Re: Is there a way to find geometric mean in proc means in SAS Programming

Is there a way to find geometric mean in proc means

chinaski — Wed, 22 Sep 2021 07:14:37 GMT

i really can't understand why proc means don't have gmean option, i want to find all things one side, if anybody knows is there a way please answer, otherwise you can shut up for your smart ass comments.

Re: Is there a way to find geometric mean in proc means

Oligolas — Wed, 22 Sep 2021 07:38:34 GMT

Hi,

there is a way but why don't you simply use surveymeans??

PROC SURVEYMEANS data=sashelp.class geomean;
 var age;
run;

if you still want to use proc means, proceed like this:

DATA class1;
 set sashelp.class;
 ln_age=log(age);
run;

PROC MEANS data=class1 mean stddev;
 var ln_age;
 output out=class2means mean=a_mean stddev=a_stddev;
run;

DATA class3;
 set class2means;
 geo_mean=exp(a_mean);
 geo_stddev=exp(a_stddev);
run;

PROC PRINT data=class3 noobs;
 var geo_mean geo_stddev;
run;

Re: Is there a way to find geometric mean in proc means

chinaski — Wed, 22 Sep 2021 07:56:25 GMT

Hi Oligolas,
Thank you for your answer, i simply can't understand why they did not put gmean option in proc means.
i have a code like this:
proc means data=WORK.datasetv02 n mean median maxdec=2;
var product_price;
class /*web_site*/ search_key product_name product_code month;
output out = work.datasetv03 (drop=_type_ _freq_) n= Toplam_Fiyat_Sayısı mean = Ortalama median = Medyan ;
FORMAT ortalama 16.2 ;
ways 4;
run;
So in here i do not only get results but a new table, now i have to do separate operations in separate tables.
Anyway i will use what you recommend but does proc surveymeans function just like proc means?
In proc means we can have output in any number of ways and thats perfect, but in proc surveymeans it doesn't work.
Thank you again.

Re: Is there a way to find geometric mean in proc means

Ksharp — Wed, 22 Sep 2021 12:30:15 GMT

Use proc univariate instead.

proc univariate data=sashelp.heart outtable=want noprint ;
var height weight;
run;

Check WANT dataset.