topic Re: How to handle special character in SAS Programming

How to handle special character

pdhokriya — Tue, 14 Sep 2021 06:01:06 GMT

Hi,

How should I handle below special charcters?

â€™ replaced by '

â€¢ by space

Â´ replace by '

data abc;
y="The Subject’s status was not changed";output;
y="The Subject has - •6 point";output;
y="The subject didn´t capture photo";output;
run;

data xyz;
set abc ;
y1=tranwrd (y, "’" , "'");
y1=tranwrd (y, "•" ,"");
y1=tranwrd (y, "´" , "'");
run;

Re: How to handle special character

Kurt_Bremser — Tue, 14 Sep 2021 07:56:27 GMT

data xyz;
set abc ;
y1=tranwrd (y, "’" , "'");
y1=tranwrd (y, "•" ,"");
y1=tranwrd (y, "´" , "'");
run;

Since you always create y1 anew from y, only the last result will show up in your output, overwriting the results of the previous translations. Change this to

data xyz;
set abc ;
y1=tranwrd (y, "’" , "'");
y1=tranwrd (y1, "•" ,"");
y1=tranwrd (y1, "´" , "'");
run;

Re: How to handle special character

pdhokriya — Sun, 19 Sep 2021 11:57:20 GMT

Yes this is not working, do you have any other solution for this senerio.

Re: How to handle special character

Tom — Sun, 19 Sep 2021 15:28:59 GMT

You seem to have an encoding issue. In your post you have two different sets of characters. One set in the description of the problem and different characters in the code.

So which ones to you have in your actual file? Look at the Hexadecimal representation of the strings to see what is actually in the file.

E28099 â€™
E280A2 â€¢
C2B4   Â´
92     ’
95     •
B4     ´

What encoding is your SAS session using? Check the value of the SYSENCODING macro variable. What encoding is the dataset that has values using? Check PROC CONTENTS output for the dataset.

You can use hexadecimal constants in your SAS code to make the code more portable.

Run the right code for the encoding that is in the character variable Y.

* UTF-8 codes ;
y1=tranwrd(y, 'E28099'x , "'");
y1=tranwrd(y1,'E280A2'x ," ");
y1=tranwrd(y1, 'C2B4'x , "'");

* WLATIN1 code ;
y1=translate(y,"' '",'929584'x);