topic Finding a set of characters in observations in SAS Programming

Finding a set of characters in observations

Gayatrikunchay — Tue, 07 Sep 2021 19:18:36 GMT

Hello,

I basically want to find a string of characters from an observation. For example, some of the observations in a diagnosis column are:

Z34.3, Z78.0, Z59.1, Z63.2

Z53.3, Z54.3, Z59.2, Z87.3

I want to find how many Z59 are there in this column. How do I write the code in SAS so that I get the frequency of Z59 irrespective of what's there after the point?

Re: Finding a set of characters in observations

PaigeMiller — Tue, 07 Sep 2021 19:37:41 GMT

data want;
    set have;
    count=0;
    do i=1 to countw(diagnosis,',');
         if scan(diagnosis,i,',')=:'Z59' then count=count+1;
    end;
    drop i;
run;

Re: Finding a set of characters in observations

sbxkoenk — Tue, 07 Sep 2021 19:40:42 GMT

Hello,

Is this what you are after?

data have;
 infile cards delimiter=','; 
 input zvar $ @@;
 z2=scan(zvar,1,'.');
cards;
Z34.3, Z78.0, Z59.1, Z63.2
Z53.3, Z54.3, Z59.2, Z87.3
;
run;

PROC FREQ data=have;
 tables z2 / out=want;
run;

proc print data=want;
run;
/* end of program */

Koen

Re: Finding a set of characters in observations

Gayatrikunchay — Tue, 07 Sep 2021 19:50:16 GMT

Hey,

Thank you for your reply. No, I actually only want to know how many Z59's are there in the column. So in this example, there are 2 but I have 800 observations. Is there another way to do it? Thanks!

Re: Finding a set of characters in observations

sbxkoenk — Tue, 07 Sep 2021 20:19:35 GMT

Something like this?

data have;
 input diagnosis $ 1-30;
cards;
Z34.3, Z78.0, Z59.1, Z63.2
Z53.3, Z54.3, Z59.2, Z87.3
;
run;

data want;
    set have;
    countZ59=0;
    do i=1 to countc(diagnosis,',');
     if scan(diagnosis,i,',')=:' Z59' 
      then countZ59=countZ59+1;
    end;
    drop i;
run;

proc means data=want SUM nway;
 var countZ59;
run;
/* end of program */

Koen

Re: Finding a set of characters in observations

ChrisNZ — Tue, 07 Sep 2021 23:00:27 GMT

Like this?

proc sql;
   select scan(ZVAR,1) as Z2, count(*) as COUNT from HAVE group by 1;

Re: Finding a set of characters in observations

Ksharp — Wed, 08 Sep 2021 12:40:03 GMT

data have;
input x $80.;
cards;
Z34.3, Z78.0, Z59.1, Z63.2
Z53.3, Z54.3, Z59.2, Z87.3
Z59.2, Z87.3, Z59.2, Z87.3
;
run;

proc sql;
select sum(count(x,'Z59')) as n from have;
quit;

Re: Finding a set of characters in observations

sbxkoenk — Wed, 08 Sep 2021 14:54:27 GMT

@Gayatrikunchay : a wealth of solutions to choose from, I would say.

Cheers,

Koen

Re: Finding a set of characters in observations

sbxkoenk — Mon, 26 Dec 2022 15:12:15 GMT

Hello,

I have just noticed my solution does not work with 'Z59' in the very first 3 positions.

Because my search is for ' Z59' (remark the leading space).

Cheers,

Koen