topic Re: SAS datetime in SAS Programming

SAS datetime

vicky07 — Tue, 11 Sep 2012 00:23:49 GMT

Hello,

I'm looking to create prev month beg and end month datetime as macro variable in the below format using today's date. Could someone please help me?

%Let PBOM_Dte = 2012-08-01 00:00:00;

%Let PEOM_Dte = 2012-08-31 23.59:59;

Thanks in advance for your help!

Linlin — Tue, 11 Sep 2012 02:52:19 GMT

data _null_;

call symputx('pbom_dte',catx(' ',put(intnx('month',today(),-1,'b'),yymmdd10.),'00:00:00'));

call symputx('peom_dte',catx(' ',put(intnx('month',today(),-1,'e'),yymmdd10.),'23:59:59'));

run;

%put &pbom_dte;

%put &peom_dte;

/* log file */

65 %put &pbom_dte;

2012-08-01 00:00:00

66 %put &peom_dte;

2012-08-31 23:59:59

Ksharp — Tue, 11 Sep 2012 03:20:09 GMT

proc format;

picture fmt

other='%Y-%0m-%0d %0H:%0M:%0S'(datatype=datetime);

run;

%let PBOM_Dte = %sysfunc(intnx(dtmonth,%sysfunc(datetime()),-1,b),fmt21. );

%put &PBOM_Dte ;

shivas — Tue, 11 Sep 2012 05:11:36 GMT

Hi Vicky,

Try this..some thing similar to Linlins code...

data _null_;

call symputx('pbom_dte',put(dhms(intnx('month',today(),-1,'b'),00,00,00),nldatm.));

call symputx('peom_dte',put(dhms(intnx('month',today(),-1,'e'),23,59,59),nldatm.));

run;

%put &pbom_dte;

%put &peom_dte;

Thanks,

Shiva

vicky07 — Tue, 11 Sep 2012 12:40:47 GMT

All the three answers worked. Thanks to Ksharp,Shiva & Linlin!!