topic Re: how to download a directory of sas files to pc using sas studio (sas on demand) in SAS Programming

How to: Download a directory of sas files (SAS Studio & SAS on demand)

MaryA_Marion — Mon, 23 Aug 2021 00:40:31 GMT

I have seen reference to using a zip file to download but not enough detail was included. Do I want to open up the interface or server? It opens to the same thing?

Any suggestions or other ideas? Thank you.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

Tom — Mon, 16 Aug 2021 00:09:22 GMT

Are you using SAS studio to access SAS or Viya? Viya does not appear to really have a file system so it will probably be harder to use a non-SAS tool to move files.

It is probably easier to upload/download a lot of files using a different user interface than SAS/Studio.

Do you have access to a file system that the server(s) that SAS/Studio is using to run SAS code lives on? Perhaps you could even connect your personal computer to one of the file systems that the SAS server is using and just use your native file copy methods. Otherwise you could use an interactive tool (like the FILEZILLA that you appear to be asking about). Essentially you just need to know what is the path that the files have on the server where SAS is running and move the files from there.

If you are forced to use SAS/Studio itself to move the files then it might help to create a ZIP file first and then you only need to copy the one file. You you might be able to use SAS code to create a ZIP file. For example if you had a lot of text files on your SAS server in a particular folder you could make a SAS file that contains those files with a data step like this:

filename in 'path to files';
filename out zip 'filename of new zip file';
data _null_;
  length fname mname $256 ;
  infile in('*') filename=fname ;
  input;
  mname = scan(fname,-1,'/\');

  file out member=mname ;
  put _infile_;
run;

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Mon, 16 Aug 2021 01:00:21 GMT

I installed fileZilla but do not know how to complete the connection to sas studio in sas on demand. Please see enclosed file. Thank you. MM

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Mon, 16 Aug 2021 01:25:02 GMT

The directory of sas files I want to download is sasmacs2 in my home directory. I am getting error messages when using your code. It asks me for fname and mname. I am not certain what to enter in there?

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

Tom — Mon, 16 Aug 2021 01:52:28 GMT

@MaryA_Marion wrote:
I installed fileZilla but do not know how to complete the connection to sas studio in sas on demand. Please see enclosed file. Thank you. MM

I was talking about connecting to some server in your company that you were using to run SAS.

Are you sure that SAS will allow you to connect to the server where SAS runs for SAS Studio on Demand without using SAS/Studio? I would be surprised if they did that.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

ChrisNZ — Mon, 16 Aug 2021 03:40:55 GMT

Filezilla requires an FTP server. Unless one has been installed, you can't use that.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

ChrisNZ — Mon, 16 Aug 2021 03:42:48 GMT

> It asks me for fname and mname.

What does ask mean?

fname and mname are populated automatically when you run the program.

Show use what you are doing.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Tue, 17 Aug 2021 14:05:16 GMT

filename in '/home/u.../sasmacs2';
filename out zip 'sasmacs2';
data _null_;
  length fname mname $256 ;
  infile in('*') filename=fname ;
  input;
  mname = scan(fname,-1,'/\');
  file out member=mname;
  put _infile_;
run;

Please see log below. I am trying to keep my u number private so you will see ... on the page. I ran the source code while in sasmacs2 directory and while in the home directory with same results.

 1          OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;
 SYMBOLGEN:  Macro variable _SASWSTEMP_ resolves to 
/home/u.../.sasstudio/.images/fefa4007-e77f-4646-84e3-e47c3f4b
23b8
 SYMBOLGEN:  Some characters in the above value which were subject to macro 
quoting have been unquoted for printing.
 SYMBOLGEN:  Macro variable GRAPHINIT resolves to GOPTIONS RESET=ALL 
GSFNAME=_GSFNAME;
 68
 69
 70
 71
 72
 73filename in '/home/u.../sasmacs2'; filename out zip 'sasmacs2';data _null_;
 74length fname mname $256 ;
 75infile in('*') filename=fname ;
 76input;
 77mname = scan(fname,-1,'/\');
 78file out member=mname;
 79put _infile_;
 80run;

 NOTE: The infile library IN is:

Directory=/home/u.../sasmacs2, Owner Name=u...,Group Name=oda, Access Permission=drwxr-xr-x,Last Modified=16Aug2021:22:42:00

 NOTE: The infile IN('*') is:

Filename=/home/u.../sasmacs2/DevianceTable.sas, File List=/home/u.../sasmacs2/*,Owner Name=u...,Group Name=oda,Access Permission=-rw-r--r--,Last Modified=25Jul2021:13:06:47,File Size (bytes)=410

 ERROR: Insufficient authorization to access sasmacs2.
 NOTE: A total of 0 records were read from the infile library IN.
 NOTE: 0 records were read from the infile IN('*').
 NOTE: The SAS System stopped processing this step because of errors.
 NOTE: DATA statement used (Total process time):
real time0.05 seconds
user cpu time0.01 seconds
system cpu time     0.02 seconds
memory578.59k
OS Memory24224.00k
Timestamp08/17/2021 01:51:55 PM
Step Count39  Switch Count  0
Page Faults0
Page Reclaims90
Page Swaps0
Voluntary Context Switches255
Involuntary Context Switches      0
Block Input Operations8
Block Output Operations8


 81
 82         OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;
 SYMBOLGEN:  Macro variable GRAPHTERM resolves to GOPTIONS NOACCESSIBLE;
 92

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Tue, 17 Aug 2021 16:10:42 GMT

I thought Filezilla was the FTP server. How do I get one? I have no experience with this except I once used CUTE ftp successfully.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

ChrisNZ — Tue, 17 Aug 2021 21:55:51 GMT

A browser client needs to connect to a web server, just like an FTP client like Filezilla needs to connect to an FTP server.

Your IT team typically manages such servers.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Tue, 17 Aug 2021 23:11:23 GMT

Okay let us say that I use cuteFTP as my file server. I will have to log
into it using a password. I don't want to purchase that software without
being reasonably certain that it will work with the SAS server. The big
question I have is how will cuteFTP interface with my online
directories? Will SAS make that possible?
MM

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

SASKiwi — Tue, 17 Aug 2021 23:12:14 GMT

As I understand it you are using SAS on Demand which operates in a locked down state with limited user permissions. So the errors you are getting are not surprising. You would be best to talk with SAS Tech Support to find out what you can and can't do in SAS on Demand.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

ChrisNZ — Tue, 17 Aug 2021 23:24:11 GMT

filename out zip 'sasmacs2';

Try providing the full path, to a folder where you can write.

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Thu, 19 Aug 2021 15:33:22 GMT

Thanks to all of you for your help. I've got the following response from SAS. "Since SAS OnDemand for Academics is a free learning software it does have some limitations as to it's capabilities and unfortunately, SAS OnDemand for Academics is not able to be used with FTP."

I have gotten SAS code to create a zip file. However, it is not opening properly using WinZip on my PC. I'm enclosing the code for you to see as well as the error message on my PC. There are no errors in the log. Zip file was downloaded using the download icon in SAS Studio.

SOURCE

filename in '/home/u.../sasmacs2';
filename out zip '/home/u.../sasmacs2.zip';
data _null_;
length fname mname $256 ;
infile in('*') filename=fname ;
input;
mname = scan(fname,-1,'/\');
file out member=mname;
put _infile_;
run;

Log:

1 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK; SYMBOLGEN: Macro variable _SASWSTEMP_ resolves to /home/u.../.sasstudio/.images/be90d0a4-57bd-49ef-8e8f-e451f5e9 6f06 SYMBOLGEN: Some characters in the above value which were subject to macro quoting have been unquoted for printing. SYMBOLGEN: Macro variable GRAPHINIT resolves to GOPTIONS RESET=ALL
78GSFNAME=_GSFNAME;filename in '/home/u.../sasmacs2'; filename out zip '/home/u.../sasmacs2.zip'; data _null_;length fname mname $256 ;infile in('*') filename=fname ;input;mname = scan(fname,-1,'/\');file out member=mname;put _infile_;run;
NOTE: The infile library IN is:
Directory=/home/u.../sasmacs2, Owner Name=u...,Group Name=oda, Access Permission=drwxr-xr-x,Last Modified=17Aug2021:15:21:32
NOTE: The infile IN('*') is:
Filename=/home/u.../sasmacs2/DevianceTable.sas, File List=/home/u.../sasmacs2/*,Owner Name=u...,Group Name=oda,Access Permission=-rw-r--r--,Last Modified=25Jul2021:13:06:47,File Size (bytes)=410
NOTE: The file OUT is:Filename=/home/u...sasmacs2.zip NOTE: The infile IN('*') is:
Filename= ... 

NOTE: 72 records were read from the infile IN('*').
The minimum record length was 0.
The maximum record length was 83.
NOTE: 8430 records were written to the file OUT.
The minimum record length was 0.
The maximum record length was 32767.
NOTE: DATA statement used (Total process time):
real time 0.17 seconds
user cpu time 0.01 seconds
system cpu time 0.04 seconds
memory 1083.37k
OS Memory 20640.00k
Timestamp 08/19/2021 02:37:22 PM
Step Count 53 Switch Count 0
Page Faults 0
Page Reclaims 249
Page Swaps 0
Voluntary Context Switches 333
Involuntary Context Switches 0
Block Input Operations 0
Block Output Operations 96
81 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;
SYMBOLGEN: Macro variable GRAPHTERM resolves to GOPTIONS NOACCESSIBLE;

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

Tom — Thu, 19 Aug 2021 15:40:57 GMT

Use MEMVAR= option, not MEMBER= option.

If that doesn't work then try using DOPEN() DNUM(), DREAD() to get the list of files instead.

filename indir '/home/u.../sasmacs2';
filename out zip '/home/u.../sasmacs2.zip';
data _null_;
  length fname mname $256 ;
  did=dopen('indir');
  putlog did=;
  do i=1 to dnum(did) ;
     mname=dread(did,i);
     if scan(mname,-1,'.')='sas' then do;
       n+1;
       putlog n= mname= ;
       fname=catx('/',pathname('indir'),mname);
       infile dummy filevar=fname end=eof;
       file out memvar=mname;
       do while (not eof);
         input ;
         put _infile_;
       end;
     end;
  end;
  did=dclose(did);
run;

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

MaryA_Marion — Thu, 19 Aug 2021 16:27:44 GMT

The suggestion Use MEMVAR= option, not MEMBER= option worked just fine. Thank you. MM

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

ChrisNZ — Fri, 20 Aug 2021 00:27:16 GMT

@BeverlyBrown @ShelleySessoms This question comes regularly and this thread might make a good pinned topic?

Re: how to download a directory of sas files to pc using sas studio (sas on demand)

ShelleySessoms — Fri, 20 Aug 2021 11:36:00 GMT

Great suggestion, @ChrisNZ. I have pinned this for all users. Thanks for thinking of efficient ways to help our members!

Re: How to: Download a directory of sas files (SAS Studio & SAS on demand)

webart999ARM — Wed, 07 Dec 2022 01:06:32 GMT

To download a directory of SAS files using SAS Studio or SAS on Demand, you can use the following steps:

Open SAS Studio or SAS on Demand in your web browser.
Navigate to the directory that contains the SAS files you want to download.
Select the SAS files you want to download by clicking on the checkbox next to each file.
Click on the "Download" button in the toolbar at the top of the page.
In the "Download" window that appears, select the "Zip" option and click on the "Download" button.
The zip file containing the SAS files will be downloaded to your computer.

Alternatively, you can use the "zip" command in SAS to create a zip file containing the SAS files. To do this, you will need to use the following code:

filename myfiles pipe "zip -r - myfiles.zip *.sas";
data null;
infile myfiles recfm=f lrecl=32767;
input;
file myfiles;
put infile;
run;

Replace "myfiles" with the name of the directory that contains the SAS files you want to download. This code will create a zip file called "myfiles.zip" that contains all the SAS files in the specified directory. You can then download the zip file to your computer using the "Download" button in SAS Studio or SAS on Demand.

Re: How to: Download a directory of sas files (SAS Studio & SAS on demand)

yabwon — Thu, 04 May 2023 08:42:24 GMT

Hey All,

The solution is here for *.sas files but sometimes there is a need for zipping a library of SAS datasets. I thought I share my solution for such task.

The BasePlus package contains two macros dedicated to zipping and unzipping a library of datasets.

How to get basePlus package? I will write below, for now assume we already have it installed and loaded into our SAS session.

The zipping macro %zipLibrary() allows to zip all data sets (v7, v8, or v9 with indexes) from SAS library into one zip file:

Lets generate some example data:

options dlcreatedir;
  libname test1 "%workpath()/test1";
  libname test2 "%workpath()/test2";
  libname test3 (test1 test2);
  libname test4 "%workpath()/test4";
options nodlcreatedir;

%put %libPath(test3);
%put %libPath(test4);

data 
  test1.A(index=(model)) 
  test1.B(where=(Origin="Asia")) 
  test2.C 
  test2.D(where=(Origin NE "Asia") index=(model make io=(invoice origin))) 
;
  set sashelp.cars;
run;

data test1.B2 / view=test1.B2;
  set test1.B;
  output;
  output;
run;

(the %libPath() and %workpath() are utility macros in BasePlus package).

To zip all datasets from test3 library and store the zip file in test4 library just execute:

%zipLibrary(test3, libOut=test4)

as a result you will get test3.zip file inside the test4 library.

When the zip is ready you can just copy it whenever you want and unzip it by hand (with 7zip for example) or you can use the %unzipLibrary() macro:

%unzipLibrary(%libPath(test4), zip=test3)

As a result you will get all elements from the test3.zip extracted into the test4 library location.

Bart

PS How to get BasePlus?

To work with SAS Packages like BasePlus or others you will need SAS Packages Framework.

Lets assume your SAS session has access to the internet (if not look below).

1) Create a directory where you want to store SPF and packages, for example let it be: "/home/myuserid/SASpackages" under Linux or "C:\Users\myuserid\SASpackages" under Windows.

2) Run the following code only one time to get the SPF:

filename packages "/home/myuserid/SASpackages"; /* setup directory for packages */
filename SPFinit url "https://raw.githubusercontent.com/yabwon/SAS_PACKAGES/main/SPF/SPFinit.sas";
%include SPFinit; /* enable the framework */

%installPackage(SPFinit) /* install SPF */
%installPackage(BasePlus) /* install BasePlus */

(installation of other packages goes the same way - by installPackage macro).

3) From now on, in this and any new SAS session, to enable SPF and BasePlus just run:

filename packages "/home/myuserid/SASpackages"; /* setup directory for packages */
%include packages(SPFinit.sas); /* enable the framework */

%loadPackage(BasePlus)    /* load the package content into the SAS session */

4) Enjoy

PS2

No access to the internet on your machine? No problem! Instead step number 2 go here and manually download SPFinit.sas file. Then go to here and download baseplus.zip file. Store them in the directory from step 1 and proceed to step 3.