topic Re: change the last digit alphabet A to the number 0 in SAS Programming

change the last digit alphabet A to the number 0

Smitha9 — Wed, 18 Aug 2021 14:50:44 GMT

Hi,

I have a data with the following ID's

SGJ604-01-A

AFD345-03-A

I want to change the last alphabet "A" to the number "0"

Can I do this in SAS. please let me know thanks in advance.

Re: change the last digit alphabet A to the number 0

Tom — Wed, 18 Aug 2021 14:55:08 GMT

Try this:

 if char(id,length(id))='A' then substr(id,length(id))='0';

Example:

458   data want;
459    set have;
460    put id= '-> ' @;
461    if char(id,length(id))='A' then substr(id,length(id))='0';
462    put id;
463   run;

id=SGJ604-01-A -> SGJ604-01-0
id=SGJ604-02-B -> SGJ604-02-B
id=AFD345-03-A -> AFD345-03-0

Re: change the last digit alphabet A to the number 0

Ron_Cody — Wed, 18 Aug 2021 15:15:09 GMT

Here is a really interesting solution that uses the SUBSTR function on the LEFT side of the = sign. I assume you mean the digit 0 (character) for the last position. Here it is:

data Test;
length String $ 11;
input String;
substr(String,11,1) = '0';
datalines;
SGJ604-01-A
AFD345-03-A
;
title "Listing of Test";
proc print data=Test;
run;

Hope this helps,

Ron

Re: change the last digit alphabet A to the number 0

ballardw — Wed, 18 Aug 2021 16:28:02 GMT

@Ron_Cody wrote:

Here is a really interesting solution that uses the SUBSTR function on the LEFT side of the = sign. I assume you mean the digit 0 (character) for the last position. Here it is:

data Test;
length String $ 11;
input String;
substr(String,11,1) = '0';
datalines;
SGJ604-01-A
AFD345-03-A
;
title "Listing of Test";
proc print data=Test;
run;

Hope this helps,

Ron

That unconditionally changes the character to 0. OP only wants the last character to change when it is 'A'

Re: change the last digit alphabet A to the number 0

Ksharp — Thu, 19 Aug 2021 13:06:50 GMT

data Test;
length String $ 11;
input String;
datalines;
SGJ604-01-A
AFD345-03-A
;
data want;
 set test;
 want=prxchange('s/a$/0/i',1,strip(string));
run;

Re: change the last digit alphabet A to the number 0

Ron_Cody — Thu, 19 Aug 2021 14:50:32 GMT

Hi. I didn't notice the specification that the last character in the string had to be 'A', so I modified my solution:

data Test;
length String $ 11;
input String;
if findc(String,'A',lengthn(String)-1) then substr(String,11,1) = '0';
datalines;
SGJ604-01-A
XXX999-090B
AFD345-03-A
;
title "Listing of Test";
proc print data=Test;
run;

The last argument in the FINDC function is a starting position. The LENGTHN function is the same as the older LENGTH function--it returns the length of a string, not counting trailing blanks. The 'N' version returns a 0 when the first argument is a missing value; the non 'N' (older function) returns a 1 in this situation. I recommend always using LENGTHN. Hope this helps and clarifies.