topic Re: How to produce two PROC REPORT outputs on the same page, each has its own subject heading in SAS Programming

How to produce two PROC REPORT outputs on the same page, each has its own subject heading

fsu — Wed, 18 Aug 2021 05:10:36 GMT

I use PROC REPORT to output results from two datasets, say A and B, to a single page. How could I insert a subject line on top of each of the tables? The "title" statement does not do the job. The expected output would look like the following. Thanks in advance!

Results Part A

PID	Measure A
101	1.1
102	1.2

Results Part B

PID	Measure B
101	2.1
102	2.2

data A B;
	do PID=101 to 102; A=PID/100; B=A+1; output; end;
run;

ods rtf file='output.rtf' startpage=NO;

title 'Results Part A';
proc report data=A;
	column PID A;
	define A /display "Measure A";
run;

title 'Results Part B';
proc report data=B;
	column PID B;
	define B /display "Measure B";
run;

ods rtf close;

Re: How to produce two PROC REPORT outputs on the same page, each has its own subject heading

ChrisNZ — Wed, 18 Aug 2021 06:36:48 GMT

Have you looked at proc odstext and ods text ?

Re: How to produce two PROC REPORT outputs on the same page, each has its own subject heading

BrunoMueller — Wed, 18 Aug 2021 13:38:48 GMT

You can also use the BODYTITLE option of the ODS RTF statement.

See here for an example:

ods rtf file='c:\temp\output.rtf' startpage=NO bodytitle;
title 'Results Part A';
proc report data=A;
	column PID A;
	define A /display "Measure A";
run;
title 'Results Part B';
proc report data=B;
	column PID B;
	define B /display "Measure B";
run;
ods rtf close;

Re: How to produce two PROC REPORT outputs on the same page, each has its own subject heading

fsu — Wed, 18 Aug 2021 14:25:16 GMT

Both solutions are nice and working. It's not permitted, but I wish I could mark both as a solution. Thank you all!