topic Re: How to get Visit information in SAS Programming

How to get Visit information

sasuser123123 — Tue, 17 Aug 2021 10:20:06 GMT

Hi ,

I have data like

data new;

input subj visit test crit $10

cards;

1 visit1 RBC

1 visit1 WBC Y

1 visit1 HEMO

1 visit2 RBC

1 visit2 WBC

1 visit2 HEMO

1 visit3 RBC

1 visit3 WBC

1 visit3 HEMO

So,if crit has value Y then we need to pull out the corresponding test across all visits, output should like...

subj visit test crit

1 visit1 WBC Y

1 visit2 WBC

1 visit3 WBC

Could anyone help me out how to do this.

Thanks.

Re: How to get Visit information

Kurt_Bremser — Tue, 17 Aug 2021 11:00:35 GMT

Please test your example data code before posting it, and fix the issues that arise.

Being able to write a simple data step is essential.

Re: How to get Visit information

andreas_lds — Tue, 17 Aug 2021 11:19:49 GMT

While fixing the issues with the data step, you may want to add another subj, or is there only one in the data you have?

At first glance this seems to be a nice task for double dow-loop.

Re: How to get Visit information

Tom — Tue, 17 Aug 2021 13:36:01 GMT

Just merge the data to the subset with CRIT='Y'.

data have;
  input subj visit $ test $ crit $ ;
cards;
1 visit1 RBC  ,
1 visit1 WBC  Y
1 visit1 HEMO .
1 visit2 RBC  .
1 visit2 WBC  .
1 visit2 HEMO .
1 visit3 RBC  .
1 visit3 WBC  .
1 visit3 HEMO .
;

proc sort;
  by subj test visit;
run;

data want;
  merge have
        have(keep=subj test crit rename=(crit=_crit) where=(_crit='Y'))
  ;
  by subj test;
  if _crit='Y';
run;

proc print;
run;

Results:

Obs    subj    visit     test    crit    _crit

 1       1     visit1    WBC      Y        Y
 2       1     visit2    WBC               Y
 3       1     visit3    WBC               Y

Re: How to get Visit information

Ksharp — Tue, 17 Aug 2021 14:09:05 GMT

data have;
  input subj visit $ test $ crit $ ;
cards;
1 visit1 RBC  ,
1 visit1 WBC  Y
1 visit1 HEMO .
1 visit2 RBC  .
1 visit2 WBC  .
1 visit2 HEMO .
1 visit3 RBC  .
1 visit3 WBC  .
1 visit3 HEMO .
;
proc sql;
create table want as
select * from have
 where test in (select test from have where crit='Y');
quit;