topic Re: Replacing IDs with the same value in SAS Programming

Replacing IDs with the same value

Anita_n — Mon, 02 Aug 2021 07:04:06 GMT

Dear all,

if I have a data that looks like this

data have;
input id 2. subjid $6. var1 $2. var2 $2. ;
datalines;
1  pat_1 A B
14 pat_2 C D
14 pat_3 E F
14 pat_4 G H
2  pat_5 I J
;
run;

and want the subjid to be the same where id is the same, how do I do that?

Re: Replacing IDs with the same value

PeterClemmensen — Mon, 02 Aug 2021 07:19:24 GMT

So for ID = 14, what subjid should be applied ?

The first one encountered?

Re: Replacing IDs with the same value

andreas_lds — Mon, 02 Aug 2021 07:25:15 GMT

The data seems to be not sorted by id, but is grouped by id? If the data is grouped try:

data want;
   set have(rename= (subjid = _subjid));
   by id notsorted;
   
   length subjid $ 6;
   retain subjid;
   
   if first.id then subjid = _subjid;
   
   drop _subjid;
run;

Re: Replacing IDs with the same value

Anita_n — Mon, 02 Aug 2021 07:31:25 GMT

yes, ID 14 should have a subjid pat_2

Re: Replacing IDs with the same value

Ksharp — Mon, 02 Aug 2021 12:06:11 GMT

Just for fun.

data have;
input id 2. subjid $6. var1 $2. var2 $2. ;
datalines;
1  pat_1 A B
14 pat_2 C D
14 pat_3 E F
14 pat_4 G H
2  pat_5 I J
;
run;

proc sql;
create table want as
select id,min(subjid) as subjid,var1,var2
 from have
  group by id;
quit;